iniciar-programa
define-nueva-instruccion media-vuelta como
inicio
    gira-izquierda;
    gira-izquierda;
fin;
define-nueva-instruccion gira-derecha como
inicio
    gira-izquierda;
    gira-izquierda;
    gira-izquierda;
fin;
define-nueva-instruccion piramide-dos(n) como
inicio
    si frente-libre entonces
    inicio
        avanza;
        mientras no-orientado-al-este hacer gira-izquierda;
        piramide-dos(n);
        repetir n veces deja-zumbador;
    fin
    sino inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        mientras frente-libre hacer avanza;
        media-vuelta;
    fin;
fin;
define-nueva-instruccion piramide(n) como
inicio
    si frente-libre entonces
    inicio
        avanza;
        piramide(sucede(n));
    fin
    sino inicio
        media-vuelta;
        mientras frente-libre hacer avanza;
        media-vuelta;
        avanza;
        piramide-dos(n);
    fin;
fin;
define-nueva-instruccion niveles(m) como
inicio
    mientras frente-libre o izquierda-libre hacer
    inicio
        si junto-a-zumbador entonces
        inicio
            repetir m veces coge-zumbador;
            si no-junto-a-zumbador entonces
            inicio
                mientras no-orientado-al-oeste hacer gira-izquierda;
                mientras frente-libre hacer avanza;
                gira-izquierda;
                mientras frente-libre hacer avanza;
                gira-izquierda;
                repetir m veces avanza;
                deja-zumbador;
                mientras no-orientado-al-oeste hacer gira-izquierda;
                mientras frente-libre hacer avanza;
                gira-derecha;
                mientras frente-libre hacer avanza;
                gira-derecha;
                mientras frente-libre hacer avanza;
                gira-derecha;
                mientras frente-libre hacer avanza;
                media-vuelta;
                avanza;
                avanza;
            fin
            sino inicio
                repetir m veces deja-zumbador;
                si frente-libre entonces
                inicio
                    avanza;
                fin
                sino inicio
                    media-vuelta;
                    mientras frente-libre hacer avanza;
                    gira-derecha;
                    si frente-libre entonces avanza;
                    gira-derecha;
                    avanza;
                    avanza;
                fin;
            fin;
        fin
        sino inicio
            si frente-libre entonces
            inicio
                avanza;
            fin
            sino inicio
                media-vuelta;
                mientras frente-libre hacer avanza;
                gira-derecha;
                si frente-libre entonces avanza;
                gira-derecha;
                avanza;
                avanza;
            fin;
        fin;
    fin;
    si orientado-al-norte y frente-bloqueado y izquierda-bloqueada entonces
    inicio
        si junto-a-zumbador entonces
        inicio
            repetir m veces coge-zumbador;
            si no-junto-a-zumbador entonces
            inicio
                mientras no-orientado-al-oeste hacer gira-izquierda;
                mientras frente-libre hacer avanza;
                gira-izquierda;
                mientras frente-libre hacer avanza;
                gira-izquierda;
                repetir m veces avanza;
                deja-zumbador;
                gira-izquierda;
            fin
            sino inicio
                repetir m veces deja-zumbador;
                media-vuelta;
                mientras frente-libre hacer avanza;
                gira-izquierda;
                repetir m veces avanza;
                gira-izquierda;
            fin;
        fin
        sino inicio
            media-vuelta;
            mientras frente-libre hacer avanza;
            gira-izquierda;
            repetir m veces avanza;
            gira-izquierda;
        fin;
    fin;
    si derecha-libre entonces
    inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-derecha;
        mientras frente-libre hacer avanza;
        gira-derecha;
        mientras frente-libre hacer avanza;
        gira-derecha;
        mientras frente-libre hacer avanza;
        media-vuelta;
        avanza;
        avanza;
        niveles(sucede(m));
    fin;
fin;
define-nueva-instruccion clonar(g) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        clonar(sucede(g));
    fin
    sino inicio
        repetir g veces deja-zumbador;
        avanza;
        media-vuelta;
        repetir g veces deja-zumbador;
        avanza;
        gira-izquierda;
        avanza;
        media-vuelta;
    fin;
fin;
define-nueva-instruccion total(d) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        total(sucede(d));
    fin
    sino inicio
        repetir d veces deja-zumbador;
        avanza;
        repetir d veces deja-zumbador;
        media-vuelta;
        avanza;
        media-vuelta;
    fin;
fin;
define-nueva-instruccion quitar(a) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        quitar(sucede(a));
    fin
    sino inicio
        avanza;
        repetir a veces coge-zumbador;
        media-vuelta;
        total(0);
        repetir a veces deja-zumbador;
    fin;
fin;
    inicia-ejecucion
        avanza;
        piramide(0);
        mientras frente-libre hacer avanza;
        gira-derecha;
        mientras frente-libre hacer avanza;
        gira-derecha;
        mientras frente-libre hacer avanza;
        media-vuelta;
        avanza;
        avanza;
        niveles(1);
        gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-derecha;
        clonar(0);
        mientras frente-libre hacer
        inicio
            quitar(0);
            avanza;
            si frente-libre entonces
            inicio
                avanza;
                media-vuelta;
            fin
            sino inicio
                apagate;
            fin;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa 