iniciar-programa
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion avanzar como mientras frente-libre hacer avanza;
define-nueva-instruccion vuelta como repetir 2 veces gira-izquierda;
define-nueva-instruccion lleva como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        lleva;
        deja-zumbador;
    fin sino inicio
        este;
        mientras no-junto-a-zumbador hacer avanza;
        coge-zumbador;
    fin;
fin;
define-nueva-instruccion dejar1(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        dejar1(sucede(x));
    fin sino inicio
        avanza;

        repetir x veces deja-zumbador;

        sur;
        avanza;
        oeste;
        deja-zumbador;
        avanza;
        avanzar;
        lleva;
    fin;
fin;
define-nueva-instruccion dobla(z) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        dobla(sucede(z));
    fin sino inicio
        repetir z veces deja-zumbador;
        oeste;
        avanzar;
        mientras junto-a-zumbador hacer coge-zumbador;
        repetir z veces deja-zumbador;
        este;
        avanza;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
    fin;
fin;
define-nueva-instruccion compara(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        compara(sucede(n));
    fin sino inicio
        avanza;
        dobla(0);
        si junto-a-zumbador entonces inicio
        repetir n veces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
            fin;
        fin;
            repetir n veces deja-zumbador;
            norte;
            dejar1(0);
        si junto-a-zumbador entonces inicio
            compara(0);
        fin;
        fin sino inicio
            norte;
        avanza;
        oeste;
        avanzar;
        este;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si junto-a-zumbador entonces inicio
            compara(0);
        fin sino inicio
            oeste;
            avanzar;
            sur;
            avanzar;
            mientras junto-a-zumbador hacer coge-zumbador;
            repetir n veces deja-zumbador;
            apagate;
        fin;
        fin;
    fin;
fin;
define-nueva-instruccion rellena(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        rellena(sucede(a));
    fin sino inicio
        repetir a veces deja-zumbador;
        oeste;
        avanza;
        repetir 10 veces inicio
            si frente-libre entonces inicio
            repetir a veces deja-zumbador;
            avanza;
            fin;
        fin;
        este;
        avanza;
        mientras junto-a-zumbador hacer avanza;
        repetir 10 veces inicio
            si frente-libre entonces inicio
            repetir a veces deja-zumbador;
            avanza;
            fin;
        fin;
    fin;
fin;
    inicia-ejecucion
    norte;
    avanzar;
    este;
    mientras no-junto-a-zumbador hacer inicio
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si no-junto-a-zumbador entonces inicio
            sur;
            avanza;
            oeste;
            avanzar;
            este;
        fin;
    fin;
    rellena(0);
    sur;
    avanzar;
    oeste;
    avanzar;
    este;
    avanza;
    mientras junto-a-zumbador y frente-libre hacer inicio
        compara(0);
    fin;

        apagate;
    termina-ejecucion
finalizar-programa
