iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion compara(j) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            compara(sucede(j));
        fin sino inicio
            repetir j veces deja-zumbador;
            oeste;
            avanza;
            repetir j veces deja-zumbador;
            este;
            avanza;
        fin;
    fin;
    define-nueva-instruccion recoge(l) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoge(sucede(l));
        fin sino inicio
            norte;
            avanza;
            repetir l veces deja-zumbador;
            sur;
            avanza;
        fin;
    fin;
    define-nueva-instruccion regresa(k) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            regresa(sucede(k));
        fin sino inicio
            este;
            avanza;
            repetir k veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion toma(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            toma(sucede(n));
        fin sino inicio
            avanza;
            si junto-a-zumbador entonces inicio
                compara(0);
                repetir n veces si junto-a-zumbador entonces coge-zumbador;
                repetir n veces deja-zumbador;
                recoge(0);
                oeste;
                avanza;
                regresa(0);
            fin sino inicio
                norte;
                avanza;
                oeste;
                avanza;
                si junto-a-zumbador entonces inicio
                    mientras junto-a-zumbador hacer avanza;
                    este;
                    avanza;
                    toma(0);
                fin sino inicio
                    sur;
                    mientras frente-libre hacer avanza;
                    oeste;
                    mientras frente-libre hacer avanza;
                    repetir n veces deja-zumbador;
                    apagate;
                fin;
            fin;
        fin;
    fin;
    inicia-ejecucion
        este;
        avanza;
        mientras junto-a-zumbador hacer toma(0);
        apagate;
    termina-ejecucion
finalizar-programa
