iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion recoge como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoge;
            deja-zumbador;
        fin sino inicio
            norte;
            avanza;
            este;
            avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion recoge2(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoge2(sucede(n));
            deja-zumbador;
        fin sino inicio
            repetir n veces deja-zumbador;
            norte;
            avanza;
        fin;
    fin;

    define-nueva-instruccion compara(n) como inicio
        si junto-a-zumbador y no si-es-cero(n) entonces inicio
            coge-zumbador;
            compara(precede(n));
            deja-zumbador;
        fin sino inicio
            si junto-a-zumbador entonces inicio
                norte;
            fin sino inicio
                sur;
            fin;
        fin;
    fin;

    define-nueva-instruccion piramide2(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            piramide2(sucede(n));
        fin sino inicio
            sur;
            avanza;
            oeste;
            avanza;
            compara(n);
            si orientado-al-sur entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                repetir n veces deja-zumbador;
            fin;
            recoge;
            este;
            avanza;
        fin;
    fin;

    define-nueva-instruccion piramide(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            piramide(sucede(n));
        fin sino inicio
            repetir n veces deja-zumbador;
            sur;
            avanza;
            oeste;
            avanza;
            repetir n veces deja-zumbador;
            este;
            avanza;
            recoge2(0);
            piramide2(0);
        fin;
    fin;

    define-nueva-instruccion final como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            final;
            deja-zumbador;
        fin sino inicio
            oeste;
            mientras frente-libre hacer avanza;
            sur;
            mientras frente-libre hacer avanza;
        fin;
    fin;

    inicia-ejecucion
        este;
        avanza;
        norte;
        avanza;
        este;
        avanza;
        mientras junto-a-zumbador hacer inicio
            piramide(0);
            si no junto-a-zumbador entonces inicio
                norte;
                avanza;
                oeste;
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                si frente-bloqueado y no junto-a-zumbador entonces inicio
                    sur;
                fin sino inicio
                    mientras frente-libre hacer avanza;
                    este;
                    mientras no junto-a-zumbador y frente-libre hacer avanza;
                fin;
            fin;
            si orientado-al-sur entonces inicio
                sur;
                avanza;
                este;
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                final;
                apagate;
            fin;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
