iniciar-programa
    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;

    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;

    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
    fin;

    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;

    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
    fin;

    define-nueva-instruccion compara(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            compara(sucede(n));
        fin sino inicio
            repetir n veces deja-zumbador;
            avanza;
            repetir n veces si junto-a-zumbador entonces coge-zumbador;
            repetir n veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion copia(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            copia(sucede(n));
            deja-zumbador;
        fin sino inicio
            norte;
            avanza;
            oeste;
        fin;
    fin;

    define-nueva-instruccion respuesta como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            respuesta;
            deja-zumbador;
        fin sino inicio
            mientras frente-libre hacer avanza;
            oeste;
            mientras frente-libre hacer avanza;
        fin;
    fin;

    define-nueva-instruccion recorre como inicio
        mientras junto-a-zumbador hacer inicio
            sur;
            avanza;
            oeste;
            avanza;
            este;
            compara(0);
            copia(0);
            avanza;
        fin;
        gira(2);
        avanza;
        mientras junto-a-zumbador hacer avanza;
        gira(2);
        avanza;
        norte;
        avanza;
        oeste;
        si no-junto-a-zumbador entonces inicio
            sur;
            avanza;
            respuesta;
            apagate;
        fin;
    fin;

    inicia-ejecucion
        este;
        avanza;
        mientras junto-a-zumbador hacer avanza;
        gira(2);
        avanza;
        norte;
        avanza;
        oeste;
        mientras junto-a-zumbador hacer recorre;
        apagate;
    termina-ejecucion
finalizar-programa
