iniciar-programa

define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

define-nueva-instruccion mayor(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        mayor(sucede(a));
    fin sino inicio
        si frente-libre entonces inicio
            avanza;
            mayor(0);
        fin sino inicio
            gira(2);
        fin;
        si si-es-cero(a) entonces inicio
            avanza;
        fin sino inicio
            si no-junto-a-zumbador entonces inicio
                repetir a veces deja-zumbador;
            fin sino inicio
                repetir a veces si junto-a-zumbador entonces coge-zumbador;
                repetir a veces deja-zumbador;
                avanza;
                repetir a veces deja-zumbador;
            fin;
        fin;
    fin;
fin;

define-nueva-instruccion subir(b) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        subir(sucede(b));
    fin sino inicio
        gira(3);
        avanza;
        gira(1);
        avanza;
        repetir b veces deja-zumbador;
        gira(2);
        avanza;
        gira(2);
    fin;
fin;

define-nueva-instruccion ordenar(c) como inicio
    si no(si-es-cero(c)) entonces inicio
        mayor(0);
        gira(2);
        repetir c veces avanza;
        gira(3);
        repetir c veces subir(0);
        avanza;
        gira(1);
        ordenar(precede(c));
    fin;
fin;

define-nueva-instruccion base(x) como inicio
    si junto-a-zumbador entonces inicio
        avanza;
        base(sucede(x));
    fin sino inicio
        gira(2);
        repetir x veces avanza;
        gira(2);
        ordenar(precede(x));
    fin;
fin;

define-nueva-instruccion final(z) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        final(sucede(z));
    fin sino inicio
        gira(1);
        mientras frente-libre hacer avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        repetir z veces deja-zumbador;
    fin;
fin;

    inicia-ejecucion

    mientras no-orientado-al-este hacer gira(1);
    avanza;
    si no-junto-a-zumbador entonces apagate;
    mientras junto-a-zumbador y frente-libre hacer avanza;
    gira(2);
    si no-junto-a-zumbador entonces avanza;
    base(0);
    final(0);

        apagate;
    termina-ejecucion
finalizar-programa

