iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierdA;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierdA;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierdA;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierdA;

    define-nueva-instruccion tomar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            tomar(sucede(n));
            deja-zumbador;
        fin sino inicio
            repetir n veces inicio
                deja-zumbador;
            fin;
            gira-izquierda;
            gira-izquierda;
            avanza;
        fin;
    fin;

    define-nueva-instruccion tomar2(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            tomar2(sucede(n));
        fin sino inicio
            repetir n veces inicio
                deja-zumbador;
            fin;
            norte;
            avanza;
            este;
            avanza;
            si junto-a-zumbador entonces inicio
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin;
            sur;
            avanza;
            este;
        fin;
    fin;

    define-nueva-instruccion tomar3 como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            tomar3;
            deja-zumbador;
        fin sino inicio
            oeste;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            sur;
            mientras frente-libre hacer inicio
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion sacar(n) como inicio
        si no si-es-cero(n) y junto-a-zumbador entonces inicio
            coge-zumbador;
            sacar(precede(n));
        fin sino inicio
            si si-es-cero(n) entonces inicio
                oeste;
                avanza;
                tomar(0);
                sur;
                tomar(0);
                sur;
                avanza;
                este;
            fin;
            si no si-es-cero(n) entonces inicio
                oeste;
                avanza;
                tomar(0);
                repetir n veces inicio
                    coge-zumbador;
                fin;
                oeste;
                avanza;
                sur;
                tomar2(0);
            fin;
        fin;
    fin;

    define-nueva-instruccion mayor(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mayor(sucede(n));
        fin sino inicio
            repetir n veces inicio
                deja-zumbador;
            fin;
            este;
            si frente-libre entonces inicio
                avanzA;
                sacar(n);
            fin;
        fin;
    fin;

    define-nueva-instruccion cambiar como inicio
        si junto-a-zumbador entonces inicio
            norte;
            avanza;
            oeste;
            mientras junto-a-zumbador hacer inicio
                avanza;
            fin;
            este;
            si no junto-a-zumbador y frente-libre entonces
                avanza;
        fin sino inicio
            oeste;
            avanza;
            norte;
            avanzA;
            oeste;
            mientras junto-a-zumbador hacer inicio
                avanza;
            fin;
            este;
            si no junto-a-zumbador y frente-libre entonces
                avanza;
        fin;
    fin;

    inicia-ejecucion
        este;
        avanza;
        mientras junto-a-zumbador hacer inicio
            mientras junto-a-zumbador y frente-libre hacer inicio
                mayor(0);
            fin;
            cambiar;
        fin;
        sur;
        avanza;
        oeste;
        avanza;
        tomar3;
        apagate;
    termina-ejecucion
finalizar-programa
