iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion mayor (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mayor (sucede(n));
        fin
        sino inicio
            repetir n veces
                deja-zumbador;
            oeste;
            avanza;
            repetir n veces inicio
                si junto-a-zumbador entonces
                    coge-zumbador;
            fin;
            repetir n veces
                deja-zumbador;
            este;
            avanza;
            avanza;
            si junto-a-zumbador entonces inicio
                mayor (0);
            fin
            sino inicio
                oeste;
                avanza;
                mientras junto-a-zumbador hacer
                    coge-zumbador;
                avanza;
                mientras junto-a-zumbador hacer
                    avanza;
                este;
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion sube (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            sube (sucede(n));
        fin
        sino inicio
            norte;
            avanza;
            este;
            avanza;
            repetir n veces
                deja-zumbador;
            sur;
            avanza;
            este;
            si junto-a-zumbador entonces inicio
                sube (0);
            fin
            sino inicio
                norte;
                avanza;
                oeste;
                mientras junto-a-zumbador hacer
                    avanza;
                este;
                avanza;
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion resultado (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            resultado (sucede(n));
        fin
        sino inicio
            sur;
            mientras frente-libre hacer
                avanza;
            oeste;
            mientras frente-libre hacer
                avanza;
            repetir n veces
                deja-zumbador;
            este;
        fin;
    fin;
    define-nueva-instruccion chispante como inicio
        este;
        avanza;
        avanza;
        mientras junto-a-zumbador hacer inicio
            mayor (0);
            sube (0);
        fin;
        oeste;
        avanza;
        resultado (0);
    fin;
    inicia-ejecucion
        chispante;
        apagate;
    termina-ejecucion
finalizar-programa