iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion skina como
    inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
        norte;
    fin;

    define-nueva-instruccion camina como
    inicio
        si frente-libre entonces avanza sino
        inicio
            sur;
            mientras frente-libre hacer avanza;
            este;
            si frente-libre entonces
            inicio
                avanza;
                norte;
            fin;
        fin;
    fin;

    define-nueva-instruccion marcar como
    inicio
        mientras no-orientado-al-este hacer
        inicio
            mientras no-junto-a-zumbador y no-orientado-al-este hacer camina;
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                si no-junto-a-zumbador entonces
                inicio
                    deja-zumbador;
                    repetir 4 veces
                    inicio
                        si frente-libre entonces
                        inicio
                            avanza;
                            si junto-a-zumbador entonces
                            inicio
                                coge-zumbador;
                                si junto-a-zumbador entonces deja-zumbador;
                                deja-zumbador;
                            fin sino repetir 2 veces deja-zumbador;
                            repetir 2 veces gira-izquierda;
                            avanza;
                            gira-izquierda;
                        fin sino repetir 3 veces gira-izquierda;
                    fin;
                fin sino deja-zumbador;
                camina;
             fin;
         fin;
     fin;

     define-nueva-instruccion recoge como
     inicio
         skina;
         mientras no-orientado-al-este hacer
         inicio
             mientras no junto-a-zumbador y no-orientado-al-este hacer camina;
             si junto-a-zumbador entonces coge-zumbador;
             camina;
         fin;
         skina;
     fin;

     define-nueva-instruccion cuenta(n) como
     inicio
         mientras no-junto-a-zumbador y no-orientado-al-este hacer camina;
         si no-orientado-al-este entonces
         inicio
             si junto-a-zumbador entonces
             inicio
                 coge-zumbador;
                 cuenta(sucede(n));
             fin;
         fin sino
         inicio
             skina;
             repetir n veces deja-zumbador;
             apagate;
          fin;
     fin;

     inicia-ejecucion
        skina;
        marcar;
        recoge;
        cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
