iniciar-programa
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion ir11 como inicio
        oeste;
        corre;
        sur;
        corre;
        norte;
    fin;
    define-nueva-instruccion rodear como inicio
        repetir 4 veces inicio
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces inicio
                    repetir 2 veces deja-zumbador;
                fin sino inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces repetir 2 veces deja-zumbador;
                    deja-zumbador;
                fin;
                repetir 2 veces gira-izquierda;
                avanza;
                repetir 2 veces gira-izquierda;
            fin;
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion recorre como inicio
        mientras no-orientado-al-oeste hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si no-junto-a-zumbador entonces rodear;
                deja-zumbador;
            fin;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                sur;
                corre;
                este;
                si frente-libre entonces inicio
                    avanza;
                    norte;
                fin sino inicio
                    oeste;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion agarra como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            coge-zumbador;
            agarra;
            deja-zumbador;
        fin sino inicio
            ir11;
        fin;
    fin;    
    define-nueva-instruccion responde como inicio
        mientras no-orientado-al-oeste hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    deja-zumbador;
                    agarra;
                fin;
            fin;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                sur;
                corre;
                este;
                si frente-libre entonces inicio
                    avanza;
                    norte;
                fin sino inicio
                    oeste;
                fin;
            fin;
        fin;
    fin;
    inicia-ejecucion
        ir11;
        recorre;
        corre;
        norte;
        responde;
        apagate;
    termina-ejecucion
finalizar-programa
