iniciar-programa
define-nueva-instruccion gira(n) como inicio
   repetir n veces
      gira-izquierda;
fin;
define-nueva-instruccion norte como inicio
   mientras no-orientado-al-norte hacer
      gira(1);
fin;
define-nueva-instruccion sur como inicio
   mientras no-orientado-al-sur hacer
      gira(1);
fin;
define-nueva-instruccion este como inicio
   mientras no-orientado-al-este hacer
      gira(1);
fin;
define-nueva-instruccion oeste como inicio
   mientras no-orientado-al-oeste hacer
      gira(1);
fin;
define-nueva-instruccion orienta como inicio
   oeste;
   mientras frente-libre hacer
      avanza;
   sur;
   mientras frente-libre hacer
      avanza;
   este;
fin;
define-nueva-instruccion sitio como inicio
   mientras no-junto-a-zumbador hacer inicio
      si frente-libre entonces inicio
         avanza;
      fin
      sino inicio
         si frente-bloqueado y orientado-al-este entonces inicio
            norte;
            si frente-libre entonces inicio
               avanza;
            fin
            sino inicio
               apagate;
            fin;
            oeste;
            sitio;
         fin;
         si frente-bloqueado y orientado-al-oeste entonces inicio
            norte;
            si frente-libre entonces inicio
               avanza;
            fin
            sino inicio
               apagate;
            fin;
            este;
            sitio;
         fin;
      fin;
   fin;
fin;
define-nueva-instruccion regresa como inicio
   si frente-libre entonces inicio
      avanza;
      regresa;
      avanza;
   fin
   sino inicio
      si orientado-al-oeste entonces inicio
         sur;
         regresa;
         este;
      fin;
      si orientado-al-sur entonces inicio
         deja-zumbador;
         norte;
      fin;
   fin;
fin;
define-nueva-instruccion cuenta como inicio
   si junto-a-zumbador entonces inicio
      coge-zumbador;
      si no-junto-a-zumbador entonces inicio
         deja-zumbador;
         deja-zumbador;
         sur;
         si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
               cuenta;
               norte;
               avanza;
            fin
            sino inicio
               oeste;
               regresa;
               norte;
               avanza;
            fin;
         fin;
         norte;
         si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
               cuenta;
               sur;
               avanza;
            fin
            sino inicio
               oeste;
               regresa;
               sur;
               avanza;
            fin;
         fin;
         este;
         si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
               cuenta;
               oeste;
               avanza;
            fin
            sino inicio
               oeste;
               regresa;
               oeste;
               avanza;
            fin;
         fin;
         oeste;
         si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
               cuenta;
               este;
               avanza;
            fin
            sino inicio
               oeste;
               regresa;
               este;
               avanza;
            fin;
         fin;
      fin
      sino inicio
         deja-zumbador;
      fin;
   fin;
fin;
    inicia-ejecucion
       orienta;
       sitio;
       cuenta;
       si junto-a-zumbador entonces
          coge-zumbador;
          coge-zumbador;
       apagate;
    termina-ejecucion
finalizar-programa