iniciar-programa
    define-nueva-instruccion norte como  mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer  inicio
        avanza;
        fin;
        oeste;
        mientras frente-libre hacer  inicio
            avanza;
        fin;
        este;
    fin;

    define-nueva-instruccion encontrar como inicio
        mientras no junto-a-zumbador hacer inicio
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                si frente-bloqueado y izquierda-libre entonces inicio
                    norte;
                    avanza;
                    oeste;
                    mientras frente-libre hacer inicio
                        avanza;
                    fin;
                    este;
                fin;
            fin;
            si orientado-al-este y frente-bloqueado y izquierda-bloqueada y no junto-a-zumbador entonces inicio
                apagate;
            fin;
        fin;
    fin;

    define-nueva-instruccion rellenar como inicio
        mientras frente-libre o izquierda-libre hacer inicio
            si junto-a-zumbador entonces inicio
                repetir 4 veces inicio
                    deja-zumbador;
                fin;
            fin;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                si frente-bloqueado y izquierda-libre entonces inicio
                    norte;
                    avanza;
                    oeste;
                    mientras frente-libre hacer inicio
                        avanza;
                    fin;
                    este;
                fin;
            fin;
        fin;
        si junto-a-zumbador entonces inicio
            repetir 4 veces inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion checar como inicio
        gira-izquierda;
        repetir 4 veces inicio
            si frente-libre entonces inicio
                avanza;
                si no junto-a-zumbador entonces inicio
                    gira-izquierda;
                    gira-izquierda;
                    avanza;
                    deja-zumbador;
                    gira-izquierda;
                 fin sino inicio
                    gira-izquierda;
                    gira-izquierda;
                    avanza;
                    gira-izquierda;
                fin;
            fin sino inicio
                gira-izquierda;
                gira-izquierda;
                gira-izquierdA;
            fin;
        fin;
        gira-izquierdA;
        gira-izquierda;
        gira-izquierdA;
        si no junto-a-zumbador entonces inicio
            repetir 6 veces inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion buscar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            buscar(sucede(n));
         fin sino inicio
            si si-es-cero(precede(precede(precede(precede(precede(n)))))) y no junto-a-zumbador entonces inicio
                checar;
                norte;
                si frente-libre entonces  inicio
                    avanza;
                    buscar(0);
                    sur;
                    avanza;
                fin;
                este;
                si frente-libre entonces inicio
                    avanza;
                    buscar(0);
                    oeste;
                    avanza;
                fin;
                sur;
                si frente-libre entonces inicio
                    avanza;
                    buscar(0);
                    norte;
                    avanza;
                fin;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    buscar(0);
                    este;
                    avanza;
                fin;
            fin;
            si no si-es-cero(precede(precede(precede(precede(precede(n)))))) entonces inicio
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion juntar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            juntar(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                juntar(0);
            fin sino inicio
                si frente-bloqueado y izquierda-libre entonces inicio
                    norte;
                    avanza;
                    oeste;
                    mientras frente-libre hacer inicio
                        avanza;
                    fin;
                    este;
                    juntar(0);
                fin;
            fin;
            ir11;
            si no si-es-cero(n) y no si-es-cero(precede(precede(precede(precede(precede(precede(n))))))) entonces inicio
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
         ir11;
         rellenar;
         ir11;
         encontrar;
         buscar(0);
         ir11;
         juntar(0);
         apagate;
    termina-ejecucion
finalizar-programa
