iniciar-programa
    define-nueva-instruccion gira(n) como inicio
      repetir n veces
        gira-izquierda;
    fin;

    define-nueva-instruccion ir11 como inicio
      mientras no-orientado-al-oeste hacer
        gira-izquierda;
      mientras frente-libre hacer
        avanza;
      gira-izquierda;
      mientras frente-libre hacer
        avanza;
      gira-izquierda;
    fin;

    define-nueva-instruccion corre como inicio
      si frente-libre entonces inicio
        avanza;
      fin sino inicio
        si orientado-al-este entonces inicio
          gira(1);
          si frente-libre entonces inicio
            avanza;
            gira(1);
          fin;
        fin sino inicio
          gira(3);
          si frente-libre entonces inicio
            avanza;
            gira(3);
          fin;
        fin;
      fin;
    fin;

    define-nueva-instruccion regresar(r) como inicio
      si junto-a-zumbador entonces inicio
        coge-zumbador;
        regresar(sucede(r));
      fin sino inicio
        deja-zumbador;
        deja-zumbador;
        gira(2);
        avanza;
        gira(2);
        repetir precede(precede(r)) veces
          deja-zumbador;
      fin;
    fin;

    define-nueva-instruccion contar(c) como inicio
      si junto-a-zumbador entonces inicio
        coge-zumbador;
        si no-junto-a-zumbador entonces inicio
          deja-zumbador;
          deja-zumbador;
          si frente-libre entonces inicio
            avanza;
            contar(1);
          fin;
          si izquierda-libre entonces inicio
            gira(1);
            avanza;
            contar(1);
            gira(3);
          fin;
          si derecha-libre entonces inicio
            gira(3);
            avanza;
            contar(1);
            gira(1);
          fin;
          si no si-es-cero(c) entonces inicio
            regresar(0);
          fin;
        fin sino inicio
          deja-zumbador;
          gira(2);
          avanza;
          gira(2);
        fin;
      fin sino inicio
        gira(2);
        avanza;
        gira(2);
        deja-zumbador;
      fin;
    fin;

    define-nueva-instruccion dejarlos(d) como inicio
      si junto-a-zumbador entonces inicio
        coge-zumbador;
        dejarlos(sucede(d));
      fin sino inicio
        deja-zumbador;
        deja-zumbador;
        ir11;
        mientras junto-a-zumbador hacer
          coge-zumbador;
        repetir d veces
          deja-zumbador;
        gira(1);
      fin;
    fin;

    define-nueva-instruccion buscarlos como inicio
      mientras no-orientado-al-norte hacer inicio
        mientras no-junto-a-zumbador y no-orientado-al-norte hacer
          corre;
        si no-orientado-al-norte entonces inicio
          contar(0);
          coge-zumbador;
          gira(2);
          si frente-bloqueado entonces
            coge-zumbador;
          dejarlos(0);
        fin;
      fin;
    fin;

    inicia-ejecucion
        ir11;
        buscarlos;
        apagate;
    termina-ejecucion
finalizar-programa
