iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion cambiar_fila como inicio
        sur;
        avanza;
        oeste;
        mientras frente-libre hacer avanza;
        este;
    fin;

    define-nueva-instruccion ir_Inicio como inicio
        oeste;
        mientras frente-libre hacer avanza;
        norte;
        mientras frente-libre hacer avanza;
        este;
    fin;

    define-nueva-instruccion buscar_Beeper(x) como inicio
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si no-junto-a-zumbador entonces inicio
            si derecha-libre entonces inicio
                cambiar_fila;
                buscar_Beeper(x);
            fin sino inicio
                oeste;
                mientras frente-libre hacer avanza;
                repetir x veces deja-zumbador;
                apagate;
            fin;
        fin;
    fin;

    define-nueva-instruccion colocar_soldados como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
                si frente-libre entonces inicio
                    avanza;
                    colocar_soldados;
                fin sino inicio
                    si derecha-libre entonces inicio
                        cambiar_fila;
                        colocar_soldados;
                    fin sino inicio
                        ir_Inicio;
                    fin;
                fin;
            fin sino inicio
                deja-zumbador;

                repetir 4 veces inicio
                    gira-izquierda;
                    si frente-libre entonces inicio
                        avanza;
                        si junto-a-zumbador entonces inicio
                            coge-zumbador;
                            si junto-a-zumbador entonces inicio
                                repetir 3 veces deja-zumbador;
                            fin sino inicio
                                deja-zumbador;
                            fin;
                        fin sino inicio
                            repetir 2 veces deja-zumbador;
                        fin;
                        gira-izquierda;
                        gira-izquierda;
                        avanza;
                        gira-izquierda;
                        gira-izquierda;
                    fin;
                fin;

                si frente-libre entonces inicio
                    avanza;
                    colocar_soldados;
                fin sino inicio
                    si derecha-libre entonces inicio
                        cambiar_fila;
                        colocar_soldados;
                    fin sino inicio
                        ir_Inicio;
                    fin;
                fin;
            fin;
        fin sino inicio
            mientras frente-libre y no-junto-a-zumbador hacer avanza;
            si junto-a-zumbador entonces inicio
                colocar_soldados;
            fin sino inicio
                si derecha-libre entonces inicio
                    cambiar_fila;
                    colocar_soldados;
                fin sino inicio
                    ir_Inicio;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion contar(soldados) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                contar(sucede(soldados));
            fin sino inicio
                buscar_Beeper(soldados);
                si junto-a-zumbador entonces inicio
                    contar(soldados);
                fin;
            fin;
        fin sino inicio
            buscar_Beeper(soldados);
            si junto-a-zumbador entonces inicio
                contar(soldados);
            fin;
        fin;
    fin;

    inicia-ejecucion
        ir_Inicio;               
        buscar_Beeper(0);
        colocar_soldados;
        contar(0);
        apagate;
    termina-ejecucion
finalizar-programa
