iniciar-programa

    define-nueva-instruccion norte como
    inicio
        mientras no-orientado-al-norte hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion sur como
    inicio
        mientras no-orientado-al-sur hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion este como
    inicio
        mientras no-orientado-al-este hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion oeste como
    inicio
        mientras no-orientado-al-oeste hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion gira-derecha como
    inicio
        repetir 3 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion gira-doble como
    inicio
        repetir 2 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion camina como
    inicio
        mientras frente-libre hacer
        inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion volver-a-k como
    inicio
        sur;
        camina;
        oeste;
        camina;
        este;
    fin;

    define-nueva-instruccion ir como
    inicio
        mientras (no(frente-bloqueado y orientado-al-este)) hacer
        inicio
            si orientado-al-oeste entonces
            inicio
               este;
               si junto-a-zumbador entonces
               inicio
                   repetir 4 veces
                   inicio
                       deja-zumbador;
                   fin;
               fin;
            fin
            sino
            inicio
                avanza;
                si junto-a-zumbador entonces
                inicio
                    repetir 4 veces
                    inicio
                        deja-zumbador;
                    fin;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion regresa como
    inicio
        oeste;
        camina;
    fin;

    define-nueva-instruccion pasa como
    inicio
        norte;
        si frente-libre entonces
        inicio
           avanza;
           oeste;
        fin
        sino
        inicio
            este;
            camina;
        fin;
    fin;

    define-nueva-instruccion cheka(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            cheka(sucede(x));
        fin
        sino
        inicio
            repetir x veces
            inicio
                deja-zumbador;
            fin;
            si (no(si-es-cero(precede(precede(precede(precede(precede(x)))))))) entonces
            inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion revisa(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
           coge-zumbador;
           revisa(sucede(x));
        fin
        sino
        inicio
            repetir x veces
            inicio
                deja-zumbador;
            fin;
            si si-es-cero(precede(precede(precede(precede(precede(x)))))) entonces
            inicio
                norte;
                si frente-libre entonces
                inicio
                    avanza;
                    cheka(0);
                    sur;
                    avanza;
                fin;
                sur;
                si frente-libre entonces
                inicio
                    avanza;
                    cheka(0);
                    norte;
                    avanza;
                fin;
                oeste;
                si frente-libre entonces
                inicio
                    avanza;
                    cheka(0);
                    este;
                    avanza;
                fin;
                este;
                si frente-libre entonces
                inicio
                    avanza;
                    cheka(0);
                    oeste;
                    avanza;
                fin;
                este;
            fin;
        fin;
    fin;

    define-nueva-instruccion ir-2 como
    inicio
        mientras (no (frente-bloqueado y orientado-al-este)) hacer
        inicio
            si orientado-al-oeste entonces
            inicio
               este;
               si junto-a-zumbador entonces
               inicio
                   revisa(0);
               fin;
            fin
            sino
            inicio
                avanza;
                si junto-a-zumbador entonces
                inicio
                    revisa(0);
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion sumbadores como
    inicio
        mientras (no((frente-bloqueado y orientado-al-este) y izquierda-bloqueada)) hacer
        inicio
            ir;
            regresa;
            pasa;
        fin;
    fin;

    define-nueva-instruccion jinal como
    inicio
        mientras (no((frente-bloqueado y orientado-al-este) y izquierda-bloqueada)) hacer
        inicio
            ir-2;
            regresa;
            pasa;
        fin;
    fin;

    define-nueva-instruccion jumiles(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
           coge-zumbador;
           jumiles(sucede(x));
        fin
        sino
        inicio
            si (no(si-es-cero(precede(precede(precede(precede(precede(x)))))))) entonces
            inicio
                repetir x veces
                inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion ir-3 como
    inicio
        mientras (no(frente-bloqueado y orientado-al-este)) hacer
        inicio
            si orientado-al-oeste entonces
            inicio
               este;
               si junto-a-zumbador entonces
               inicio
                   jumiles(0);
               fin;
            fin
            sino
            inicio
                avanza;
                si junto-a-zumbador entonces
                inicio
                    jumiles(0);
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion recoge como
    inicio
    mientras (no((frente-bloqueado y orientado-al-este) y izquierda-bloqueada)) hacer
        inicio
            ir-3;
            regresa;
            pasa;
        fin;
    fin;

    define-nueva-instruccion papa(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
           coge-zumbador;
           papa(sucede(x));
        fin
        sino
        inicio
            si (frente-bloqueado y orientado-al-oeste) entonces
            inicio
               este;
               papa(x);
            fin
            sino
            inicio
                si (frente-bloqueado y orientado-al-este) entonces
                inicio
                    regresa;
                    norte;
                    si frente-libre entonces
                    inicio
                       avanza;
                       oeste;
                       papa(x);
                    fin
                    sino
                    inicio
                        volver-a-k;
                        repetir x veces
                        inicio
                            deja-zumbador;
                        fin;
                        apagate;
                    fin;
                fin
                sino
                inicio
                    avanza;
                    papa(x);
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
        volver-a-k;
        oeste;
        sumbadores;
        volver-a-k;
        oeste;
        jinal;
        volver-a-k;
        oeste;
        recoge;
        volver-a-k;
        oeste;
        papa(0);
        apagate;
    termina-ejecucion
finalizar-programa
