iniciar-programa
    define-nueva-instruccion media-vuelta como
        repetir 2 veces
            gira-izquierda;
    define-nueva-instruccion gira-derecha como
        repetir 3 veces
            gira-izquierda;
    define-nueva-instruccion regresa como inicio
        media-vuelta;
        avanza;
        media-vuelta;
    fin;
    define-nueva-instruccion soldado como
         repetir 4 veces inicio
             si frente-libre entonces inicio
                 avanza;
                 si no-junto-a-zumbador entonces inicio
                     media-vuelta;
                     avanza;
                     deja-zumbador;
                     gira-izquierda;
                 fin
                 sino inicio
                     media-vuelta;
                     avanza;
                     gira-izquierda;
                 fin;
             fin
             sino
                 gira-derecha;
        fin;

    define-nueva-instruccion busca como
    repetir 4 veces inicio
        si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                        deja-zumbador;
                        regresa;
                fin
                sino inicio
                    repetir 2 veces
                        deja-zumbador;
                    busca;
                    gira-izquierda;
                    soldado;
                    gira-derecha;
                    regresa;
                fin;
            fin
            sino inicio
                regresa;
            fin;
        fin;
        gira-izquierda;
      fin;
    define-nueva-instruccion recorrido como
        si frente-libre o izquierda-libre o junto-a-zumbador o no-orientado-al-este entonces inicio
            si junto-a-zumbador  entonces inicio
                si orientado-al-este entonces inicio
                    repetir 2 veces
                        coge-zumbador;
                    media-vuelta;
                fin;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    recorrido;
                    deja-zumbador;
                fin
                sino inicio
                    si no-orientado-al-este entonces
                        media-vuelta;
                    recorrido;
                fin;
            fin
            sino inicio
                si no-orientado-al-este entonces
                    media-vuelta;
                si frente-libre  entonces
                    avanza
                sino
                    si izquierda-libre entonces inicio
                        media-vuelta;
                        mientras frente-libre hacer
                            avanza;
                       gira-derecha;
                       avanza;
                       gira-derecha;
                    fin;
               recorrido;
            fin;
      fin
      sino inicio
          mientras no-orientado-al-oeste hacer
              gira-izquierda;
          mientras frente-libre hacer
              avanza;
          gira-izquierda;
          mientras frente-libre hacer
              avanza;
      fin;
    inicia-ejecucion
        mientras no-orientado-al-oeste hacer
            gira-izquierda;
        mientras frente-libre hacer
            avanza;
        gira-izquierda;
        mientras frente-libre hacer
            avanza;
        gira-izquierda;
        mientras frente-libre o izquierda-libre o junto-a-zumbador  o no-orientado-al-este hacer inicio
            si junto-a-zumbador entonces inicio
                 busca;
                 si junto-a-zumbador entonces inicio
                     coge-zumbador;
                     si no-junto-a-zumbador entonces inicio
                         deja-zumbador;
                         deja-zumbador;
                         gira-izquierda;
                         soldado;
                        gira-derecha;
                   fin
                   sino
                       deja-zumbador;
                fin;
                recorrido;
                apagate;
            fin;
            si frente-libre  entonces
                avanza
            sino
                si izquierda-libre entonces inicio
                    media-vuelta;
                    mientras frente-libre hacer
                        avanza;
                   gira-derecha;
                   avanza;
                   gira-derecha;
                fin;
       fin;

        apagate;
    termina-ejecucion
finalizar-programa
