iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion orienta como inicio
        sur;
        mientras frente-libre hacer
            avanza;
        oeste;
        mientras frente-libre hacer
            avanza;
        norte;
    fin;
    define-nueva-instruccion revisa (n) como inicio
        si orientado-al-norte entonces inicio
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces inicio
                    sur;
                    avanza;
                    revisa (sucede(n));
                fin
                sino inicio
                    sur;
                    avanza;
                fin;
            fin
            sino inicio
                sur;
            fin;
        fin;
        si orientado-al-sur entonces inicio
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces inicio
                    norte;
                    avanza;
                    este;
                    revisa (sucede(n));
                fin
                sino inicio
                    norte;
                    avanza;
                    este;
                fin;
            fin
            sino inicio
                este;
            fin;
        fin;
        si orientado-al-este entonces inicio
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces inicio
                    oeste;
                    avanza;
                    revisa (sucede(n));
                fin
                sino inicio
                    oeste;
                    avanza;
                fin;
            fin
            sino inicio
                oeste;
            fin;
        fin;
        si orientado-al-oeste entonces inicio
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces inicio
                    este;
                    avanza;
                    deja-zumbador;
                    norte;
                    orienta;
                    repetir n veces
                        deja-zumbador;
                    deja-zumbador;
                    avanza;
                fin
                sino inicio
                    este;
                    avanza;
                    deja-zumbador;
                    norte;
                    orienta;
                    repetir n veces
                        deja-zumbador;
                    avanza;
                fin;
            fin
            sino inicio
                este;
                deja-zumbador;
                orienta;
                repetir n veces
                    deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion recorre como inicio
        si frente-libre entonces inicio
            si frente-libre entonces
                avanza;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    deja-zumbador;
                fin
                sino inicio
                    deja-zumbador;
                    revisa (0);
                fin;
            fin;
            recorre;
        fin
        sino inicio
            si derecha-libre entonces inicio
                sur;
                mientras frente-libre hacer
                    avanza;
                este;
                avanza;
                norte;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        deja-zumbador;
                    fin
                    sino inicio
                        deja-zumbador;
                        revisa (0);
                    fin;
                fin;
                recorre;
            fin;
        fin;
    fin;
    inicia-ejecucion
        orienta;
        si frente-bloqueado y derecha-bloqueada y izquierda-bloqueada y junto-a-zumbador entonces inicio
            coge-zumbador;
            apagate;
        fin;
        si junto-a-zumbador entonces inicio
            revisa (0);
            recorre;
            orienta;
            repetir 2 veces
                coge-zumbador;
        fin
        sino inicio
            recorre;
            orienta;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa