iniciar-programa
    define-nueva-instruccion gira-derecha como repetir 3 veces gira-izquierda;
    define-nueva-instruccion vuelta como repetir 2 veces gira-izquierda;
    define-nueva-instruccion principio como
    inicio
        vuelta;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        mientras frente-libre hacer avanza;
        vuelta;
    fin;

    define-nueva-instruccion bloqueado como
    inicio
        si frente-bloqueado entonces
        inicio
            si orientado-al-norte entonces gira-derecha;
            si orientado-al-sur entonces gira-izquierda;
            si frente-libre entonces
            inicio
                avanza;
                si izquierda-bloqueada entonces gira-derecha;
                si derecha-bloqueada entonces gira-izquierda;
            fin sino
            inicio
                sal-de-instruccion;
            fin;
        fin;
    fin;

    define-nueva-instruccion avanzando como
    inicio
        si frente-libre entonces
        inicio
            si no-junto-a-zumbador entonces avanza;
            si junto-a-zumbador entonces sal-de-instruccion;
        fin;
    fin;

    define-nueva-instruccion soldados como
    inicio
        si junto-a-zumbador entonces
        inicio
            repetir 3 veces deja-zumbador;
            si frente-libre entonces avanza;
        fin;
        si no-junto-a-zumbador y frente-libre entonces avanzando;
        si frente-bloqueado entonces
        inicio
            si junto-a-zumbador entonces repetir 3 veces deja-zumbador;
            bloqueado;
        fin;
        si frente-bloqueado y orientado-al-este entonces sal-de-instruccion;
        soldados;
    fin;

    define-nueva-instruccion verificando como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                si junto-a-zumbador entonces
                inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces
                    inicio
                        repetir 3 veces deja-zumbador;
                        sal-de-instruccion;
                    fin sino
                    inicio
                        repetir 3 veces deja-zumbador;
                    fin;
                fin sino
                inicio
                    repetir 2 veces deja-zumbador;
                fin;
            fin sino
            inicio
                deja-zumbador;
            fin;
            deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion marcando como
    inicio
        si no-junto-a-zumbador entonces
        inicio
            vuelta;
            deja-zumbador;
        fin sino
        inicio
            si junto-a-zumbador entonces
            inicio
                verificando;
                vuelta;
            fin;
        fin;
    fin;

    define-nueva-instruccion cuatro como
    inicio
        si frente-libre entonces
        inicio
            avanza;
            marcando;
            avanza;
        fin sino
        inicio
            vuelta;
        fin;
        si frente-libre entonces
        inicio
            avanza;
            marcando;
            avanza;
        fin sino
        inicio
            vuelta;
        fin;
    fin;

    define-nueva-instruccion verificando2 como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                si junto-a-zumbador entonces
                inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces
                    inicio
                        repetir 3 veces deja-zumbador;
                        cuatro;
                        gira-izquierda;
                        cuatro;
                        gira-derecha;
                    fin sino
                    inicio
                        repetir 3 veces deja-zumbador;
                    fin;
                fin sino
                inicio
                    repetir 2 veces deja-zumbador;
                fin;
            fin sino
            inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion bardeando como
    inicio
        si junto-a-zumbador entonces verificando2;
        si frente-libre entonces avanza;
        si no-junto-a-zumbador y frente-libre entonces avanzando;
        si frente-bloqueado entonces
        inicio
            si junto-a-zumbador entonces verificando2;
            bloqueado;
        fin;
        si frente-bloqueado y orientado-al-este entonces sal-de-instruccion;
        bardeando;
    fin;

    define-nueva-instruccion verificando3 como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                si junto-a-zumbador entonces
                inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces
                    inicio
                        coge-zumbador;
                    fin sino
                    inicio
                        repetir 3 veces deja-zumbador;
                    fin;
                fin sino
                inicio
                    repetir 2 veces deja-zumbador;
                fin;
            fin sino
            inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion quitando como
    inicio
        si junto-a-zumbador entonces
        inicio
            verificando3;
            si frente-libre entonces avanza;
        fin;
        si no-junto-a-zumbador y frente-libre entonces avanzando;
        si frente-bloqueado entonces
        inicio
            si junto-a-zumbador entonces verificando3;
            bloqueado;
        fin;
        si frente-bloqueado y orientado-al-este entonces sal-de-instruccion;
        quitando;
    fin;

    define-nueva-instruccion contando(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            contando(sucede(n));
        fin;
        si no-junto-a-zumbador y frente-libre entonces avanzando;
        si frente-bloqueado entonces
        inicio
            si junto-a-zumbador entonces contando(n);
            bloqueado;
        fin;
        si orientado-al-este entonces
        inicio
            principio;
            repetir n veces deja-zumbador;
            apagate;
        fin;
        contando(n);
    fin;
    inicia-ejecucion
        soldados;
        principio;
        bardeando;
        principio;
        quitando;
        principio;
        contando(0);
        apagate;
    termina-ejecucion
finalizar-programa
 