iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion busca como
    inicio
          si junto-a-zumbador entonces
            inicio
                  coge-zumbador;
                  si junto-a-zumbador entonces
                    inicio
                        deja-zumbador;
                    fin sino
                        inicio
                            deja-zumbador;
                            apagate;
                        fin;
            fin sino
                inicio
                    repetir 2 veces deja-zumbador;
                    norte;
                    si frente-libre entonces
                        inicio
                            avanza;
                            busca;
                            sur;
                            avanza;
                        fin;
                    este;
                    si frente-libre entonces
                        inicio
                            avanza;
                            busca;
                            oeste;
                            avanza;
                        fin;
                    sur;
                    si frente-libre entonces
                        inicio
                            avanza;
                            busca;
                            norte;
                            avanza;
                        fin;
                    oeste;
                    si frente-libre entonces
                        inicio
                            avanza;
                            busca;
                            este;
                            avanza;
                        fin;

                fin;
    fin;
    inicia-ejecucion
    busca;
        apagate;
    termina-ejecucion
finalizar-programa