iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion marcar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no junto-a-zumbador entonces inicio
                apagate;
            fin sino deja-zumbador;
        fin;
        si no junto-a-zumbador entonces inicio
            deja-zumbador;
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                marcar;
                sur;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                marcar;
                oeste;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                marcar;
                norte;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                marcar;
                este;
                avanza;
            fin;
        fin;
    fin;
    inicia-ejecucion
        marcar;
        apagate;
    termina-ejecucion
finalizar-programa
