iniciar-programa
define-nueva-instruccion norte como inicio
    mientras no orientado-al-norte hacer inicio
        gira-izquierda;
    fin;
fin;
define-nueva-instruccion este como inicio
    mientras no orientado-al-este hacer inicio
        gira-izquierda;
    fin;
fin;
define-nueva-instruccion oeste como inicio
    mientras no orientado-al-oeste hacer inicio
        gira-izquierda;
    fin;
fin;
define-nueva-instruccion sur como inicio
    mientras no orientado-al-sur hacer inicio
        gira-izquierda;
    fin;
fin;
define-nueva-instruccion buscar como inicio
    si ((junto-a-zumbador y frente-bloqueado) y derecha-bloqueada) y izquierda-bloqueada entonces inicio
        apagate;
    fin;
    si  junto-a-zumbador entonces inicio
        (*ve s.i. es casilla visitada o la salida*)
        coge-zumbador;
            (* solo entra cuando esta junto a zumbador *)
            si junto-a-zumbador entonces inicio
                deja-zumbador;
                apagate;
            fin sino inicio
                deja-zumbador;
            fin;
    fin sino inicio
        (*se ejecuta cuando n,o esta junto a zumbador*)
            deja-zumbador;
        (*las orientaciones se dejaron afuera para el momento del back tracking se pasara a la orientacion siguiente*)
        norte;
        si frente-libre entonces inicio
            avanza;
            buscar;
            (*Back tracking*)
            sur;
            avanza;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            buscar;
            (*Back tracking*)
            norte;
            avanza;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            buscar;
            (*Back tracking*)
            oeste;
            avanza;
        fin;
        oeste;
        si frente-libre entonces inicio
            avanza;
            buscar;
            (*Back tracking*)
            este;
            avanza;
        fin;
    fin;
fin;
    inicia-ejecucion
    buscar;
        apagate;
    termina-ejecucion
finalizar-programa
