iniciar-programa
    define-nueva-instruccion norte como  mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion buscar como inicio
        si no junto-a-zumbador entonces inicio
            deja-zumbador;
            deja-zumbador;
            deja-zumbador;
        fin;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio                                
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    deja-zumbador;
                    norte;
                    si frente-libre entonces  inicio
                        avanza;
                        buscar;
                        sur;
                        avanza;
                    fin;
                    este;
                    si frente-libre entonces inicio
                        avanza;
                        buscar;
                        oeste;
                        avanza;
                    fin;
                    sur;
                    si frente-libre entonces  inicio
                        avanza;
                        buscar;
                        norte;
                        avanza;
                    fin;
                    oeste;
                    si frente-libre entonces  inicio
                        avanza;
                        buscar;
                        este;
                        avanza;
                    fin;
                fin sino inicio
                    deja-zumbador;
                    deja-zumbador;
                fin;
            fin sino inicio
                apagate;
            fin;
        fin;
    fin;

    inicia-ejecucion
         buscar;
         apagate;
    termina-ejecucion
finalizar-programa
