iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion deja(n) como inicio
        repetir n veces deja-zumbador;
    fin;

    define-nueva-instruccion compara(n) como inicio
       si no si-es-cero(n) entonces inicio
           repetir n veces inicio
               si junto-a-zumbador entonces coge-zumbador;
           fin;
           si junto-a-zumbador entonces inicio
               deja(n);
           fin sino inicio
               deja(n);
           fin;
       fin;
       oeste;
       avanza;
    fin;

    define-nueva-instruccion busqueda(n) como inicio
        si junto-a-zumbador y no si-es-cero(n) entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        coge-zumbador;
                        si junto-a-zumbador entonces inicio
                            deja(4);
                        fin sino inicio
                            deja(3);
                        fin;
                    fin sino inicio
                        deja(3);
                        si no si-es-cero(n) entonces inicio
                            este;
                            avanza;
                            si junto-a-zumbador entonces inicio
                                compara(precede(n));
                            fin sino inicio
                                repetir precede(n) veces deja-zumbador;
                                oeste;
                                avanza;
                            fin;
                        fin;
                    fin;
                fin sino inicio
                    deja(6);
                    norte;
                    si frente-libre entonces inicio
                        avanza;
                        busqueda(precede(n));
                        sur;
                        avanza;
                    fin;
                    sur;
                    si frente-libre entonces inicio
                        avanza;
                        busqueda(precede(n));
                        norte;
                        avanza;
                    fin;
                    este;
                    si frente-libre entonces inicio
                        avanza;
                        busqueda(precede(n));
                        oeste;
                        avanza;
                    fin;
                    oeste;
                    si frente-libre entonces inicio
                        avanza;
                        busqueda(precede(n));
                        este;
                        avanza;
                    fin;
                    repetir 4 veces coge-zumbador;
                fin;
            fin sino inicio
                deja(5);
                norte;
                si frente-libre entonces inicio
                    avanza;
                    busqueda(n);
                    sur;
                    avanza;
                fin;
                sur;
                si frente-libre entonces inicio
                    avanza;
                    busqueda(n);
                    norte;
                    avanza;
                fin;
                este;
                si frente-libre entonces inicio
                    avanza;
                    busqueda(n);
                    oeste;
                    avanza;
                fin;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    busqueda(n);
                    este;
                    avanza;
                fin;
                repetir 4 veces coge-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion cuenta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(n));
        fin sino inicio
            avanza;
            busqueda(n);
        fin;
    fin;

    inicia-ejecucion
        cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
