iniciar-programa

    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;

    define-nueva-instruccion paso como inicio
        si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces sal-de-instruccion;
            gira(2);
            avanza;
            gira(2);
        fin;

        gira(1);
        si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces sal-de-instruccion;
            gira(2);
            avanza;
            gira(2);
        fin;

        gira(2);
        si frente-libre entonces avanza;
    fin;

    define-nueva-instruccion sigue-linea como inicio
        mientras junto-a-zumbador hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    deja-zumbador;
                    sal-de-instruccion;
                fin;
                deja-zumbador;
                paso;
            fin;
        fin;
    fin;

    define-nueva-instruccion deja-al-este(n) como inicio
        si no-orientado-al-este entonces inicio
            gira-izquierda;
            deja-al-este(n);
            gira-izquierda
        fin sino inicio
            avanza;
            repetir n veces si junto-a-zumbador entonces coge-zumbador;
            repetir n veces deja-zumbador;
            gira(2);
            avanza;
        fin;
    fin;

    define-nueva-instruccion busqueda(n) como inicio
        si junto-a-zumbador y no si-es-cero (n)entonces inicio
            repetir 2 veces coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si no-junto-a-zumbador entonces inicio
                    deja-al-este(n);
                    si orientado-al-oeste entonces gira(2);
                fin;
                gira(2);
                repetir 3 veces deja-zumbador;
                avanza;
            fin sino inicio
                repetir 4 veces deja-zumbador;

                si frente-libre entonces inicio
                    avanza;
                    si junto-a-zumbador entonces inicio
                        sigue-linea;
                        busqueda(precede(n));
                        sigue-linea;
                        gira(2);
                    fin sino inicio
                        gira(2);
                        avanza;
                        gira(2);
                    fin;
                fin;

                gira(1);
                si frente-libre entonces inicio
                    avanza;
                    si junto-a-zumbador entonces inicio
                        sigue-linea;
                        busqueda(precede(n));
                        sigue-linea;
                        gira(2);
                    fin sino inicio
                        gira(2);
                        avanza;
                        gira(2);
                    fin;
                fin;

                 gira(2);
                 si frente-libre entonces inicio
                    avanza;
                    si junto-a-zumbador entonces inicio
                        sigue-linea;
                        busqueda(precede(n));
                        sigue-linea;
                        gira(2);
                    fin sino inicio
                        gira(2);
                        avanza;
                        gira(2);
                    fin;
                fin;

                gira(3);

                repetir 2 veces coge-zumbador;
                avanza;
            fin;
        fin sino inicio
            si si-es-cero(n) entonces inicio
                gira(2);
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion cuenta-k(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta-k(sucede(n));
        fin sino inicio
            avanza;
            sigue-linea;
            busqueda(precede(n));
        fin;
    fin;

    inicia-ejecucion
        cuenta-k(0);
        apagate;
    termina-ejecucion
finalizar-programa
