iniciar-programa
define-prototipo-instruccion busqueda(x);
define-nueva-instruccion gira(q) como repetir q veces gira-izquierda;

define-nueva-instruccion orienta(x) como inicio
    si no orientado-al-este entonces inicio
        gira(1);
        orienta(x);
        gira(3);
    fin sino inicio
        avanza;
        si junto-a-zumbador entonces inicio
            repetir x veces inicio
                si no junto-a-zumbador entonces inicio
                    mientras no orientado-al-norte hacer gira-izquierda;
                fin;
                si orientado-al-este entonces coge-zumbador;
                si orientado-al-norte entonces deja-zumbador;
            fin;
            si orientado-al-este entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                repetir x veces deja-zumbador;
            fin sino inicio
                repetir x veces inicio
                    si no junto-a-zumbador entonces inicio
                        mientras no orientado-al-este hacer gira-izquierda;
                    fin;
                    si orientado-al-este entonces deja-zumbador;
                    si orientado-al-norte entonces coge-zumbador;
                fin;
            fin;
        fin sino inicio
            repetir x veces deja-zumbador;
        fin;
        gira(2);
        avanza;
        gira(2);
    fin;
fin;

define-nueva-instruccion comprueba(x) como inicio
    avanza;
    si junto-a-zumbador entonces inicio
        busqueda(x);
    fin;
    gira(2);
    avanza;
    gira(2);
fin;

define-nueva-instruccion busqueda(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                repetir 2 veces deja-zumbador;
                orienta(sucede(x));
            fin sino inicio
                busqueda(sucede(x));
                repetir 2 veces deja-zumbador;
            fin;
        fin sino inicio
            busqueda(x);
            deja-zumbador;
        fin;
    fin sino inicio
        si frente-libre entonces comprueba(x);
        gira(1);
        si frente-libre entonces comprueba(x);
        gira(2);
        si frente-libre entonces comprueba(x);
        gira(1);
    fin;
fin;

define-nueva-instruccion buscar(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                mientras no orientado-al-este hacer gira-izquierda;
                avanza;
                repetir x veces inicio
                    si no junto-a-zumbador entonces inicio
                        mientras no orientado-al-norte hacer gira-izquierda;
                    fin;
                    si orientado-al-este entonces coge-zumbador;
                    si orientado-al-norte entonces deja-zumbador;
                fin;
                apagate;
            fin sino inicio
                buscar(x);
                repetir 2 veces deja-zumbador;
            fin;
        fin sino inicio
            buscar(x);
            deja-zumbador;
        fin;
    fin sino inicio
        si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
                buscar(x);
            fin;
            gira(2);
            avanza;
            gira(2);
        fin;
        gira(1);
        si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
                buscar(x);
            fin;
            gira(2);
            avanza;
            gira(2);
        fin;
        gira(2);
        si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
                buscar(x);
            fin;
            gira(2);
            avanza;
            gira(2);
        fin;
        gira(1);
    fin;
fin;

define-nueva-instruccion cuenta(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        cuenta(sucede(x));
    fin sino inicio
        avanza;
        buscar(x);
    fin;
fin;

    inicia-ejecucion
    avanza;
    busqueda(0);
    gira(2);
    avanza;
    gira(2);
    cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
