iniciar-programa

define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

define-nueva-instruccion regresar (c) como inicio
    si no(si-es-cero(c)) y junto-a-zumbador entonces inicio
        coge-zumbador;
        regresar(precede(c));
    fin sino inicio
        repetir c veces deja-zumbador;
    fin;
fin;

define-nueva-instruccion comparar(b) como inicio
    si no(si-es-cero(b)) y junto-a-zumbador entonces inicio
        coge-zumbador;
        comparar(precede(b));
    fin sino inicio
        si si-es-cero(b) y junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
        fin sino inicio
            si si-es-cero(b) y no-junto-a-zumbador entonces inicio
                deja-zumbador;
            fin sino inicio
                repetir sucede(b) veces deja-zumbador;
            fin;
        fin;
    fin;
fin;

define-nueva-instruccion caminos(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si no-junto-a-zumbador entonces inicio
            repetir 4 veces inicio
                si frente-libre entonces inicio
                    avanza;
                    caminos(a);
                    gira(2);
                    avanza;
                    gira(2);
                fin;
                gira(1);
            fin;
            deja-zumbador;
        fin sino inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces inicio
                 repetir 4 veces inicio
                     si frente-libre entonces inicio
                        avanza;
                        caminos(sucede(a));
                        gira(2);
                        avanza;
                        gira(2);
                    fin;
                    gira(1);
                fin;
                repetir 2 veces deja-zumbador;
            fin sino inicio
                coge-zumbador;
                si no-junto-a-zumbador entonces repetir a veces deja-zumbador;
                comparar(a);
                si no-junto-a-zumbador entonces inicio
                    repetir a veces deja-zumbador;
                fin sino inicio
                    coge-zumbador;
                    regresar(a);
                fin;
                repetir 3 veces deja-zumbador;
            fin;
        fin;
    fin;
fin;

define-nueva-instruccion restar(z) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        restar(sucede(z));
    fin sino inicio
        avanza;
        repetir z veces si junto-a-zumbador entonces coge-zumbador;
    fin;
fin;

define-nueva-instruccion torreon(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces coge-zumbador;
        si no-junto-a-zumbador entonces inicio
            repetir 4 veces inicio
                 si frente-libre entonces inicio
                     avanza;
                     torreon(x);
                     gira(2);
                     avanza;
                     gira(2);
                 fin;
                 gira(1);
            fin;
            deja-zumbador;
        fin sino inicio
            coge-zumbador;
            mientras no-orientado-al-este hacer gira(1);
            avanza;
            repetir x veces deja-zumbador;
            gira(2);
            avanza;
            gira(2);
            restar(0);
            apagate;
        fin;
    fin;
fin;

define-nueva-instruccion viajes(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        viajes(sucede(x));
    fin sino inicio
        avanza;
        caminos(1);
        torreon(x);
    fin;
fin;

    inicia-ejecucion

    viajes(0);

        apagate;
    termina-ejecucion
finalizar-programa
