iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion mover como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mover;
            deja-zumbador;
        fin sino inicio
            avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion resultado como inicio
        si junto-a-zumbador entonces inicio
            repetir 3 veces si junto-a-zumbador entonces coge-zumbador;
            si junto-a-zumbador entonces inicio
                mientras no-orientado-al-este hacer gira(1);
                mover;
                apagate;
            fin;
            repetir 4 veces inicio
                gira-izquierda;
                si frente-libre entonces inicio
                    avanza;
                    resultado;
                    gira(2);
                    avanza;
                    gira(2);
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion compara(ahorro) como inicio
        si no(si-es-cero(ahorro)) entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                compara(precede(ahorro));
                deja-zumbador;
            fin sino inicio
                repetir ahorro veces deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion busca(ahorro) como inicio
        si no(si-es-cero(ahorro)) entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        coge-zumbador;
                        si junto-a-zumbador entonces inicio
                            (*llego mas de una ves*)
                            compara(ahorro);
                            repetir 3 veces deja-zumbador;
                        fin sino inicio
                            (*llego la primera ves*)
                            repetir ahorro veces deja-zumbador;
                            repetir 3 veces deja-zumbador;
                        fin;
                    fin sino inicio
                        norte;
                        si frente-libre entonces inicio
                            avanza;
                            busca(precede(ahorro));
                            sur;
                            avanza;
                        fin;
                        sur;
                        si frente-libre entonces inicio
                            avanza;
                            busca(precede(ahorro));
                            norte;
                            avanza;
                        fin;
                        este;
                        si frente-libre entonces inicio
                            avanza;
                            busca(precede(ahorro));
                            oeste;
                            avanza;
                        fin;
                        oeste;
                        si frente-libre entonces inicio
                            avanza;
                            busca(precede(ahorro));
                            este;
                            avanza;
                        fin;
                        repetir 2 veces deja-zumbador;
                    fin;
                fin sino inicio
                    norte;
                    si frente-libre entonces inicio
                        avanza;
                        si junto-a-zumbador entonces busca(ahorro);
                        sur;
                        avanza;
                    fin;
                    sur;
                    si frente-libre entonces inicio
                        avanza;
                        si junto-a-zumbador entonces busca(ahorro);
                        norte;
                        avanza;
                    fin;
                    este;
                    si frente-libre entonces inicio
                        avanza;
                        si junto-a-zumbador entonces busca(ahorro);
                        oeste;
                        avanza;
                    fin;
                    oeste;
                    si frente-libre entonces inicio
                        avanza;
                        si junto-a-zumbador entonces busca(ahorro);
                        este;
                        avanza;
                    fin;
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion cuenta(kamiones) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(kamiones));
        fin sino inicio
            deja-zumbador;
            si no(si-es-cero(precede(kamiones))) entonces inicio
                busca(precede(kamiones));
            fin sino inicio
                resultado;
            fin;
        fin;
    fin;

    inicia-ejecucion
        cuenta(0);
        resultado;
        apagate;
    termina-ejecucion
finalizar-programa
