iniciar-programa

    define-nueva-instruccion gira-derecha como
    inicio
        repetir 3 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion gira-doble como
    inicio
        repetir 2 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion norte como
    inicio
        mientras no-orientado-al-norte hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion sur como
    inicio
        mientras no-orientado-al-sur hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion este como
    inicio
        mientras no-orientado-al-este hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion oeste como
    inicio
        mientras no-orientado-al-oeste hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion camina como
    inicio
        mientras frente-libre hacer
        inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion busqueda(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                si junto-a-zumbador entonces
                inicio
                   este;
                   avanza;
                   si no-junto-a-zumbador entonces
                   inicio
                       repetir sucede(x) veces
                       inicio
                           deja-zumbador;
                       fin;
                   fin;
                   repetir sucede(x) veces
                   inicio
                       si junto-a-zumbador entonces
                       inicio
                          coge-zumbador;
                       fin
                       sino
                       inicio
                           repetir x veces
                           inicio
                               deja-zumbador;
                           fin;
                           norte;
                       fin;
                    fin;
                    si orientado-al-norte entonces
                    inicio
                       oeste;
                       avanza;
                    fin
                    sino
                    inicio
                        mientras junto-a-zumbador hacer
                        inicio
                            coge-zumbador;
                        fin;
                        repetir sucede(x) veces
                        inicio
                            deja-zumbador;
                        fin;
                        oeste;
                        avanza;
                    fin;
                    deja-zumbador;
                    deja-zumbador;
                fin
                sino
                inicio
                    norte;
                si frente-libre entonces
                inicio
                    avanza;
                    busqueda(sucede(x));
                    sur;
                    avanza;
                fin;
                sur;
                si frente-libre entonces
                inicio
                    avanza;
                    busqueda(sucede(x));
                    norte;
                    avanza;
                fin;
                este;
                si frente-libre entonces
                inicio
                    avanza;
                    busqueda(sucede(x));
                    oeste;
                    avanza;
                fin;
                oeste;
                si frente-libre entonces
                inicio
                    avanza;
                    busqueda(sucede(x));
                    este;
                    avanza;
                fin;
                deja-zumbador;
                deja-zumbador;
                fin;
            fin
            sino
            inicio
                norte;
                si frente-libre entonces
                inicio
                    avanza;
                    busqueda(x);
                    sur;
                    avanza;
                fin;
                sur;
                si frente-libre entonces
                inicio
                    avanza;
                    busqueda(x);
                    norte;
                    avanza;
                fin;
                este;
                si frente-libre entonces
                inicio
                    avanza;
                    busqueda(x);
                    oeste;
                    avanza;
                fin;
                oeste;
                si frente-libre entonces
                inicio
                    avanza;
                    busqueda(x);
                    este;
                    avanza;
                fin;
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion resta como
    inicio
        si junto-a-zumbador entonces
        inicio
           coge-zumbador;
           resta;
           coge-zumbador;
        fin
        sino
        inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion pasa como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            pasa;
            deja-zumbador;
        fin
        sino
        inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion ciudad(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
            repetir 2 veces
            inicio
                si junto-a-zumbador entonces
                inicio
                    coge-zumbador;
                fin;
            fin;
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                repetir x veces
                inicio
                    deja-zumbador;
                fin;
                este;
                avanza;
                oeste;
                resta;
                este;
                pasa;
                apagate;
            fin
            sino
            inicio
                norte;
                si frente-libre entonces
                inicio
                    avanza;
                    ciudad(x);
                    sur;
                    avanza;
                fin;
                sur;
                si frente-libre entonces
                inicio
                    avanza;
                    ciudad(x);
                    norte;
                    avanza;
                fin;
                este;
                si frente-libre entonces
                inicio
                    avanza;
                    ciudad(x);
                    oeste;
                    avanza;
                fin;
                oeste;
                si frente-libre entonces
                inicio
                    avanza;
                    ciudad(x);
                    este;
                    avanza;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion principio(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
           coge-zumbador;
           principio(sucede(x));
        fin
        sino
        inicio
            si frente-libre entonces
            inicio
                avanza;
            fin;
            busqueda(0);
            ciudad(x);
        fin;
    fin;

    inicia-ejecucion
        principio(0);
        apagate;
    termina-ejecucion
finalizar-programa
