iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion compara (n) como inicio
        repetir n veces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
            fin;
        fin;
        repetir n veces
            deja-zumbador;
    fin;
    define-nueva-instruccion busca (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si no-junto-a-zumbador entonces inicio
                        repetir 3 veces
                            deja-zumbador;
                        si orientado-al-este entonces inicio
                            avanza;
                            si no si-es-cero (n) entonces inicio
                                compara (precede(n));
                            fin
                            sino inicio
                                compara (n);
                            fin;
                            gira (2);
                            avanza;
                            gira (2);
                        fin;
                        si orientado-al-sur entonces inicio
                            este;
                            avanza;
                            si no si-es-cero (n) entonces inicio
                                compara (precede(n));
                            fin
                            sino inicio
                                compara (n);
                            fin;
                            gira (2);
                            avanza;
                            gira (1);
                        fin;
                        si orientado-al-norte entonces inicio
                            este;
                            avanza;
                            si no si-es-cero (n) entonces inicio
                                compara (precede(n));
                            fin
                            sino inicio
                                compara (n);
                            fin;
                            gira (2);
                            avanza;
                            gira (3);
                        fin;
                    fin
                    sino inicio
                        repetir 3 veces
                            deja-zumbador;
                    fin;
                fin
                sino inicio
                    si no si-es-cero (n) entonces inicio
                        repetir 4 veces
                            deja-zumbador;
                        si frente-libre entonces inicio
                            avanza;
                            busca (precede(n));
                            gira (2);
                            avanza;
                            gira (2);
                        fin;
                        gira (3);
                        si frente-libre entonces inicio
                            avanza;
                            busca (precede(n));
                            gira (2);
                            avanza;
                            gira (3);
                        fin
                        sino inicio
                            gira (1);
                        fin;
                        gira (1);
                        si frente-libre entonces inicio
                            avanza;
                            busca (precede(n));
                            gira (2);
                            avanza;
                            gira (1);
                        fin
                        sino inicio
                            gira (3);
                        fin;
                        repetir 2 veces
                            coge-zumbador;
                    fin
                    sino inicio
                        repetir 2 veces
                            deja-zumbador;
                    fin;
                fin;
            fin
            sino inicio
                si frente-libre entonces inicio
                    avanza;
                    busca (n);
                    gira (2);
                    avanza;
                    gira (2);
                fin;
                gira (3);
                si frente-libre entonces inicio
                    avanza;
                    busca (n);
                    gira (2);
                    avanza;
                    gira (3);
                fin
                sino inicio
                    gira (1);
                fin;
                gira (1);
                si frente-libre entonces inicio
                    avanza;
                    busca (n);
                    gira (2);
                    avanza;
                    gira (1);
                fin
                sino inicio
                    gira (3);
                fin;
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion torreon (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            torreon (sucede(n));
        fin
        sino inicio
            avanza;
            busca (n);
        fin;
    fin;
    define-nueva-instruccion reloaded como inicio
        torreon (0);
    fin;
    inicia-ejecucion
        reloaded;
        apagate;
    termina-ejecucion
finalizar-programa