iniciar-programa
define-prototipo-instruccion asientos(x);
define-nueva-instruccion gira(q) como repetir q veces gira-izquierda;

define-nueva-instruccion frente como inicio
    avanza;
    si no junto-a-zumbador entonces inicio
        gira(2);
        avanza;
        gira(2);
    fin;
fin;

define-nueva-instruccion izquierda como inicio
    gira(1);
    avanza;
    si no junto-a-zumbador entonces inicio
        gira(2);
        avanza;
        gira(1);
    fin;
fin;

define-nueva-instruccion derecha como inicio
    gira(3);
    avanza;
    si no junto-a-zumbador entonces inicio
        gira(2);
        avanza;
        gira(3);
    fin;
fin;

define-nueva-instruccion ubica como inicio
    si frente-libre y no junto-a-zumbador entonces frente;
    si izquierda-libre y no junto-a-zumbador entonces izquierda;
    si derecha-libre y no junto-a-zumbador entonces derecha;
fin;

define-nueva-instruccion falta(x) como inicio
        ubica;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                falta(sucede(x));
            fin sino inicio
                falta(x);
            fin;
        fin sino inicio
            si si-es-cero(x) entonces inicio
                mientras no orientado-al-este hacer gira-izquierda;
                avanza;
                repetir 5 veces deja-zumbador;
                apagate;
            fin sino inicio
                repetir x veces deja-zumbador;
                apagate;
            fin;
        fin;
fin;

define-nueva-instruccion asientos(x) como inicio
    si si-es-cero(x) entonces inicio
        falta(x);
    fin sino inicio
        ubica;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                asientos(precede(x));
            fin sino inicio
                asientos(x);
            fin;
        fin sino inicio
            mientras no orientado-al-este hacer gira-izquierda;
            avanza;
            repetir 5 veces deja-zumbador;
            apagate;
        fin;
    fin;
fin;

define-nueva-instruccion tam(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        tam(sucede(x));
    fin sino inicio
        asientos(x);
    fin;
fin;
    inicia-ejecucion
    tam(0);
        apagate;
    termina-ejecucion
finalizar-programa
