iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion faltantes(cuantos) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                deja-zumbador;
                faltantes(sucede(cuantos));
            fin sino inicio
                deja-zumbador;
                si frente-libre entonces inicio
                    avanza;
                    faltantes(cuantos);
                    gira(2);
                    avanza;
                    gira(2);
                fin;

                si derecha-libre entonces inicio
                    gira(3);
                    avanza;
                    faltantes(cuantos);
                    gira(2);
                    avanza;
                    gira(3);
                fin;

                si izquierda-libre entonces inicio
                    gira(1);
                    avanza;
                    faltantes(cuantos);
                    gira(2);
                    avanza;
                    gira(1);
                fin;

                si si-es-cero(cuantos) entonces inicio
                    coge-zumbador;
                    mientras no-orientado-al-este hacer gira-izquierda;
                    avanza;
                    mientras junto-a-zumbador hacer coge-zumbador;
                    repetir 5 veces deja-zumbador;
                fin sino inicio
                    coge-zumbador;
                    repetir cuantos veces deja-zumbador;
                fin;
                apagate;
            fin;
        fin;
    fin;

    define-nueva-instruccion busca(pasajeros) como inicio
        si no(si-es-cero(pasajeros)) entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    mientras junto-a-zumbador hacer coge-zumbador;
                    deja-zumbador;
                    busca(precede(pasajeros));
                fin sino inicio
                    deja-zumbador;
                    si frente-libre entonces inicio
                        avanza;
                        busca(pasajeros);
                        gira(2);
                        avanza;
                        gira(2);
                    fin;

                    si derecha-libre entonces inicio
                        gira(3);
                        avanza;
                        busca(pasajeros);
                        gira(2);
                        avanza;
                        gira(3);
                    fin;

                    si izquierda-libre entonces inicio
                        gira(1);
                        avanza;
                        busca(pasajeros);
                        gira(2);
                        avanza;
                        gira(1);
                    fin;

                    coge-zumbador;
                    mientras no-orientado-al-este hacer gira-izquierda;
                    avanza;
                    mientras junto-a-zumbador hacer coge-zumbador;
                    repetir 5 veces deja-zumbador;
                    apagate;
                fin;
            fin;
        fin sino inicio
            faltantes(0);
        fin;
    fin;

    define-nueva-instruccion cuenta(pasajeros) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(pasajeros));
        fin sino inicio
            deja-zumbador;
            busca(pasajeros);
        fin;
    fin;

    inicia-ejecucion
        cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
