iniciar-programa
define-nueva-instruccion a como avanza;
define-nueva-instruccion gi como gira-izquierda;
define-nueva-instruccion mv como repetir 2 veces gi;
define-nueva-instruccion gd como repetir 3 veces gi;
define-nueva-instruccion sa como mientras frente-libre hacer a;
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gi;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gi;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gi;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gi;
define-nueva-instruccion pasar como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        pasar;
        deja-zumbador;
    fin
    sino
    inicio
        mv;
        a;
        mv;
    fin;
fin;
define-nueva-instruccion exhausto(x) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        si junto-a-zumbador entonces
        inicio
        coge-zumbador;
        mv;
        repetir 3 veces
        inicio
            gi;
            si frente-libre entonces
            inicio
                a;
                exhausto(x);
                pasar;
            fin;
        fin;
        gd;
        repetir 2 veces deja-zumbador;
        fin
        sino
        inicio
            mv;
            repetir 3 veces
            inicio
                gi;
                si frente-libre entonces
                inicio
                    a;
                    exhausto(x);
                    pasar;
                fin;
            fin;
            gd;
        fin;
    fin;
fin;
define-nueva-instruccion mitad(x) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        coge-zumbador;
        mitad(sucede(x));
    fin
    sino
    inicio
        sur;
        sa;
        oeste;
        sa;
        norte;
        repetir x veces si junto-a-zumbador entonces coge-zumbador;
        repetir x veces deja-zumbador;
    fin;
fin;
define-nueva-instruccion barrer como
inicio
    si junto-a-zumbador entonces inicio exhausto(0); mitad(0); fin;
    si frente-libre entonces
    inicio
        a;
        barrer;
    fin
    sino
    inicio
        mv;
        sa;
        gi;
        si frente-libre entonces inicio a; gi; barrer; fin
        sino apagate;
    fin;
fin;
    inicia-ejecucion
    sur;
    sa;
    oeste;
    sa;
    norte;
    barrer;
           apagate;
    termina-ejecucion
finalizar-programa
