iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion acarreo como inicio
        repetir 2 veces gira-izquierda;
        avanza;
        mientras junto-a-zumbador hacer inicio
            coge-zumbador;
            repetir 2 veces gira-izquierda;
            avanza;
            deja-zumbador;
            repetir 2 veces gira-izquierda;
            avanza;
        fin;
        repetir 2 veces gira-izquierda;
        avanza;
    fin;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion busca como inicio
        norte;
        si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
            coge-zumbador;
            acarreo;
            busca;
            sur;
            avanza;
            acarreo;
            fin sino inicio
                sur;
                avanza;
            fin;
        fin;
        oeste;
        si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
            coge-zumbador;
            acarreo;
            busca;
            este;
            avanza;
            acarreo;
            fin sino inicio
                este;
                avanza;
            fin;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
            coge-zumbador;
            acarreo;
            busca;
            norte;
            avanza;
            acarreo;
            fin sino inicio
                norte;
                avanza;
            fin;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
            coge-zumbador;
            acarreo;
            busca;
            oeste;
            avanza;
            acarreo;
            fin sino inicio
                oeste;
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
    fin;
    define-nueva-instruccion compara(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            compara(sucede(n));
        fin sino inicio
            ir11;
            repetir n veces inicio
                si junto-a-zumbador entonces coge-zumbador;
            fin;
            repetir n veces deja-zumbador;
            este;
            avanza;
        fin;
    fin;
    define-nueva-instruccion bunker como inicio
        mientras no-junto-a-zumbador hacer inicio
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                norte;
                si frente-libre entonces inicio
                    avanza;
                    oeste;
                    mientras frente-libre hacer avanza;
                    este;
                fin sino inicio
                    apagate;
                fin;
            fin;
        fin;
        si junto-a-zumbador entonces inicio
            busca;
            si junto-a-zumbador entonces coge-zumbador;
            compara(0);
            bunker;
        fin;
    fin;
    inicia-ejecucion
        ir11;
        este;
        bunker;
        apagate;
    termina-ejecucion
finalizar-programa
