iniciar-programa

define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;


define-nueva-instruccion mueve como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        mueve;
        deja-zumbador;
    fin sino inicio
        avanza;
    fin;
fin;

define-nueva-instruccion busca como inicio

    si junto-a-zumbador entonces inicio

        coge-zumbador;

        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
               deja-zumbador;
               deja-zumbador;
               sal-de-instruccion;
            fin sino deja-zumbador;
            busca;
            deja-zumbador;
            deja-zumbador;
        fin;

        norte;
        si frente-libre entonces inicio
            avanza;
            busca;
            sur;
            mueve;
        fin;

        sur;
        si frente-libre entonces inicio
            avanza;
            busca;
            norte;
            mueve;
        fin;

                                                                                       
        este;
        si frente-libre entonces inicio
            avanza;
            busca;
            oeste;
            mueve;
        fin;


        oeste;
        si frente-libre entonces inicio
            avanza;
            busca;
            este;
            mueve;
        fin;

    fin;

fin;




define-nueva-instruccion mayor(x) como inicio

    si junto-a-zumbador y no si-es-cero(x) entonces inicio
        coge-zumbador;
        mayor(precede(x));
        deja-zumbador;
    fin sino inicio
        repetir x veces deja-zumbador;
    fin;

fin;

define-nueva-instruccion ir11 como inicio
    sur;
    mientras frente-libre hacer avanza;
    oeste;
    mientras frente-libre hacer avanza;
    este;
fin;

define-nueva-instruccion compara(n) como inicio
  si junto-a-zumbador entonces inicio
      coge-zumbador;
      coge-zumbador;
      compara(sucede(n));
  fin sino inicio
    ir11;
    mayor(n);
  fin;

fin;


define-nueva-instruccion recorreLinea como inicio
    mientras frente-libre hacer inicio
        si junto-a-zumbador entonces inicio
            busca;
            compara(0);
        fin;
        avanza;
    fin;

        si junto-a-zumbador entonces inicio
            busca;
            compara(0);
        fin;

fin;

define-nueva-instruccion cambia como inicio
    oeste;
    mientras frente-libre hacer avanza;
    norte;
    si frente-bloqueado entonces apagate;
    avanza;
    este;
fin;

    inicia-ejecucion

    ir11;
    mientras algun-zumbador-en-la-mochila hacer inicio

        recorreLinea;
        cambia;

    fin;

        apagate;
    termina-ejecucion
finalizar-programa
