iniciar-programa
define-nueva-instruccion norte como
    mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como
    mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como
    mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como
    mientras no orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion back como inicio
    repetir 2 veces gira-izquierda;
fin;
define-nueva-instruccion pasar como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        pasar;
        deja-zumbador;
    fin sino inicio
        back;
        avanza;
    fin;
fin;
define-nueva-instruccion bunker como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        back;
        si frente-libre entonces inicio
            avanza;
            pasar;
        fin;
        norte;
        si frente-libre entonces inicio
            avanza;
            bunker;
            sur;
            avanza;
            back;
            avanza;
            pasar;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            bunker;
            norte;
            avanza;
            back;
            avanza;
            pasar;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            bunker;
            oeste;
            avanza;
            back;
            avanza;
            pasar;
        fin;
        oeste;
        si frente-libre entonces inicio
            avanza;
            bunker;
            este;
            avanza;
            back;
            avanza;
            pasar;
        fin;
    fin;
fin;
define-nueva-instruccion buscar como inicio
    este;
    mientras no junto-a-zumbador y frente-libre  hacer inicio
       si frente-libre entonces  avanza;
        si frente-bloqueado entonces inicio
            si orientado-al-este entonces inicio
                norte;
                si frente-libre entonces inicio
                    avanza;
                    oeste;
                fin sino inicio
                    si junto-a-zumbador entonces inicio  bunker; fin sino inicio apagate; fin;
                fin;
            fin sino inicio
                norte;
                si frente-libre entonces inicio
                    avanza;
                    este;
                fin sino inicio
                    si junto-a-zumbador entonces inicio  bunker; fin sino inicio apagate; fin;
                fin;
            fin;
        fin;
    fin;
    si junto-a-zumbador entonces inicio
        bunker;
    fin sino inicio
        apagate;
    fin;
fin;
define-nueva-instruccion ir11 como inicio
    oeste;
    mientras frente-libre hacer avanza;
    sur;
    mientras frente-libre hacer avanza;
fin;
define-nueva-instruccion compara(a) como inicio
    repetir a veces inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
        fin;
   fin;
   repetir a veces deja-zumbador;
fin;
define-nueva-instruccion armas(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        armas(sucede(a));
    fin sino inicio
        ir11;
        si no junto-a-zumbador entonces inicio
            repetir a veces deja-zumbador;
        fin sino inicio
            compara(a);
        fin;
    fin;
fin;

    inicia-ejecucion
    ir11;
        este;
    mientras no orientado-al-norte hacer inicio
        buscar;
        si junto-a-zumbador entonces inicio
        armas(0);
        este;
        avanza;
        fin;
    fin;
        apagate;
    termina-ejecucion
finalizar-programa
