iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion ir11 como inicio
        oeste;
        corre;
        sur;
        corre;
        norte;
    fin;
    define-nueva-instruccion regresa como inicio
        repetir 2 veces gira-izquierda;
        avanza;
    fin;
    define-prototipo-instruccion busca;
    define-nueva-instruccion camina como inicio
        repetir 4 veces inicio
            si frente-libre entonces inicio
                avanza;
                busca;
                regresa;
                repetir 2 veces gira-izquierda;
            fin;
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion mueve como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mueve;
            deja-zumbador;
        fin sino inicio
            regresa;
        fin;
     fin;
    define-nueva-instruccion checa-ant como inicio
        si junto-a-zumbador entonces inicio
            regresa;
            si junto-a-zumbador entonces inicio
                regresa;
                repetir 2 veces coge-zumbador;
            fin sino inicio
                regresa;
            fin;
            mueve;
            regresa;
        fin;
    fin;
    define-nueva-instruccion busca como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    repetir 2 veces deja-zumbador;
                fin sino inicio
                    regresa;
                    si junto-a-zumbador entonces inicio
                        deja-zumbador;
                    fin sino inicio
                        repetir 3 veces deja-zumbador;
                    fin;
                    regresa;
                    camina;
                    checa-ant;
                fin;
            fin sino inicio
                camina;
                checa-ant;
            fin;
        fin;
    fin;
    define-nueva-instruccion muevete como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            sur;
            corre;
            este;
            si frente-libre entonces inicio
                avanza;
                norte;
            fin sino inicio
                oeste;
            fin;
        fin;
    fin;
    define-nueva-instruccion busca-bunker como inicio
        mientras no-orientado-al-oeste hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        repetir 2 veces deja-zumbador;
                        muevete;
                    fin sino inicio
                        repetir 3 veces deja-zumbador;
                        camina;
                    fin;
                fin sino inicio
                    camina;
                fin;
                norte;
            fin sino inicio
                muevete;
            fin;
        fin;
    fin;
    define-nueva-instruccion quita2 como inicio
        mientras no-orientado-al-oeste hacer inicio
            si junto-a-zumbador entonces inicio
                repetir 2 veces coge-zumbador;
            fin;
            muevete;
        fin;
    fin;
    define-prototipo-instruccion mayor(x);
    define-nueva-instruccion leer(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            leer(sucede(x));
        fin sino inicio
            muevete;
            si no-orientado-al-oeste entonces inicio
                mayor(x);
            fin sino inicio
                corre;
                repetir x veces deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion mayor(x) como inicio
        si junto-a-zumbador entonces inicio
            repetir x veces si junto-a-zumbador entonces coge-zumbador;
            repetir x veces deja-zumbador;
            leer(0);
        fin sino inicio
            muevete;
            si no-orientado-al-oeste entonces inicio
                mayor(x);
            fin sino inicio
                corre;
                repetir x veces deja-zumbador;
            fin;
        fin;
     fin;
    inicia-ejecucion
        ir11;
        busca-bunker;
        corre;
        norte;
        quita2;
        corre;
        norte;
        mayor(0);
        apagate;
    termina-ejecucion
finalizar-programa
