iniciar-programa
define-prototipo-instruccion busca(x);
define-nueva-instruccion gira(q) como repetir q veces gira-izquierda;
define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion pasa como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        pasa;
        deja-zumbador;
    fin sino inicio
        gira(2);
        avanza;
        gira(2);
    fin;
fin;
define-nueva-instruccion adelante como inicio
    si frente-libre entonces inicio
        avanza;
        si junto-a-zumbador entonces busca(0);
        si no junto-a-zumbador entonces  inicio
            gira(2);
            avanza;
            gira(2);
        fin sino inicio
            pasa;
        fin;
    fin;
fin;
define-nueva-instruccion izquierda como inicio
    si izquierda-libre entonces inicio
        gira(1);
        avanzA;
        si junto-a-zumbador entonces busca(0);
        si no junto-a-zumbador entonces inicio
            gira(2);
            avanza;
            gira(1);
        fin sino inicio
            pasa;
            gira(3);
        fin;
    fin;
fin;
define-nueva-instruccion derecha como inicio
    si derecha-libre entonces inicio
        gira(3);
        avanzA;
        si junto-a-zumbador entonces busca(0);
        si no junto-a-zumbador entonces inicio
            gira(2);
            avanza;
            gira(3);
        fin sino inicio
            pasa;
            gira(1);
        fin;
    fin;
fin;
define-nueva-instruccion busca(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        busca(sucede(x));
    fin sino inicio
        adelante;
        izquierda;
        derecha;
        si si-es-cero(precede(precede(x))) entonces inicio
            deja-zumbador;
        fin;
    fin;
fin;
define-nueva-instruccion compara(x) como inicio
    si no si-es-cero(x) entonces inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            compara(precede(x));
            deja-zumbador;
        fin sino inicio
            compara(precede(x));
            deja-zumbador;
        fin;
    fin;
fin;
define-nueva-instruccion uno_uno como inicio
    sur;
    mientras frente-libre hacer avanza;
    oeste;
    mientras frente-libre hacer avanza;
    este;
fin;
define-nueva-instruccion lleva(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        lleva(sucede(x));
    fin sino inicio
        uno_uno;
        compara(x);
        si frente-libre entonces avanzA;
    fin;
fin;
define-nueva-instruccion junto como inicio
    mientras no junto-a-zumbador y frente-libre hacer avanza;
    si junto-a-zumbador entonces inicio
        busca(0);
        lleva(0);
        junto;
    fin sino inicio
        gira(1);
        si frente-libre entonces inicio
            avanza;
            oeste;
            mientras frente-libre hacer avanza;
            este;
            junto;
        fin;
    fin;
fin;
    inicia-ejecucion
    uno_uno;
    junto;
        apagate;
    termina-ejecucion
finalizar-programa
