iniciar-programa

define-nueva-instruccion gira(z) como repetir z veces gira-izquierda;

define-nueva-instruccion dividir como inicio
    si junto-a-zumbador entonces inicio
        repetir 3 veces coge-zumbador;
        dividir;
        deja-zumbador;
    fin;
fin;

define-nueva-instruccion traer_armas como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        traer_armas;
        deja-zumbador;
    fin sino inicio
        gira(2);
        avanza;
        gira(2);
    fin;
fin;

define-nueva-instruccion reducir_bunker(a) como inicio
    repetir 4 veces inicio
        si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        repetir 2 veces deja-zumbador;
                    fin sino inicio
                        repetir 3 veces deja-zumbador;
                        reducir_bunker(0);
                    fin;
                fin sino inicio
                    reducir_bunker(0);
                fin;
            fin;
            gira(2);
            avanza;
            gira(2);
        fin;
        gira(1);
    fin;
    si junto-a-zumbador y si-es-cero(a) entonces inicio
        traer_armas;
        avanza;
    fin;
fin;

define-nueva-instruccion fase_uno como inicio
    mientras orientado-al-este hacer inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces repetir 2 veces deja-zumbador;
            reducir_bunker(1);
            dividir;
        fin;
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            si izquierda-libre entonces inicio
                gira-izquierda;
                avanza;
                gira-izquierda;
                mientras frente-libre hacer avanza;
                gira(2);
            fin sino inicio
                gira(2);
            fin;
        fin;
    fin;      
fin;

define-nueva-instruccion fase_dos(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        fase_dos(sucede(a));
    fin sino inicio
        si frente-libre entonces inicio
            avanza;
            fase_dos(0);
        fin sino inicio
            si izquierda-libre entonces inicio
                gira-izquierda;
                avanza;
                gira-izquierda;
                mientras frente-libre hacer avanza;
                gira(2);
                fase_dos(0);
            fin;
        fin;
        si no si-es-cero(a) entonces inicio
            repetir a veces si junto-a-zumbador entonces coge-zumbador;
            repetir a veces deja-zumbador;
        fin;
    fin;
fin;

    inicia-ejecucion

    mientras no-orientado-al-oeste hacer gira-izquierda;
    repetir 2 veces inicio
        mientras frente-libre hacer avanza;
        gira-izquierda;
    fin;

    fase_uno;
    fase_dos(0);

        apagate;
    termina-ejecucion
finalizar-programa
