iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion media-vuelta como inicio
        repetir 2 veces inicio
            gira-izquierdA;
        fin;
    fin;

    define-nueva-instruccion pasar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            pasar;
            deja-zumbador;
        fin sino inicio
            media-vuelta;
            avanza;
        fin;
    fin;

    define-nueva-instruccion bunker como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            media-vuelta;
            si frente-libre entonces inicio
                avanza;
                pasar;
            fin;
            norte;
            si frente-libre entonces inicio
                avanza;
                bunker;
                sur;
                avanza;
                media-vuelta;
                avanza;
                pasar;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                bunker;
                oeste;
                avanza;
                media-vuelta;
                avanza;
                pasar;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                bunker;
                norte;
                avanza;
                media-vuelta;
                avanza;
                pasar;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                bunker;
                este;
                avanza;
                media-vuelta;
                avanza;
                pasar;
            fin;
        fin;
    fin;

    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
    fin;

    define-nueva-instruccion comparar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            comparar(sucede(n));
            deja-zumbador;
        fin sino inicio
            ir11;
            repetir n veces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion avanzar como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            norte;
            avanza;
            oeste;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            este;
        fin;
    fin;

    inicia-ejecucion
        ir11;
        mientras frente-libre o izquierda-libre hacer inicio
            bunker;
            si junto-a-zumbador entonces inicio
                comparar(0);
            fin;
            este;
            avanzar;
        fin;
        bunker;
        comparar(0);
        apagate;
    termina-ejecucion
finalizar-programa
