iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion Ini como inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;                            
        mientras frente-libre hacer avanza;
        norte;
    fin;

    define-nueva-instruccion buscaBeeper como inicio
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si no-junto-a-zumbador entonces inicio
            si derecha-libre entonces inicio
                este;
                avanza;
                sur;
                mientras frente-libre hacer avanza;
                norte;
                buscaBeeper;
            fin sino inicio
                Ini;
                apagate;
            fin;
        fin;
    fin;

    define-nueva-instruccion mover como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mover;
            deja-zumbador;
        fin sino inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion busqueda_Armas como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                norte;
                si frente-libre entonces inicio
                    avanza;
                    busqueda_Armas;
                    sur;
                    mover;
                fin;

                sur;
                si frente-libre entonces inicio
                    avanza;
                    busqueda_Armas;
                    norte;
                    mover;
                fin;

                este;
                si frente-libre entonces inicio
                    avanza;
                    busqueda_Armas;
                    oeste;
                    mover;
                fin;

                oeste;
                si frente-libre entonces inicio
                    avanza;
                    busqueda_Armas;
                    este;
                    mover;
                fin;

                repetir 2 veces deja-zumbador;
            fin sino inicio
                norte;
                si frente-libre entonces inicio
                    avanza;
                    busqueda_Armas;
                    sur;
                    mover;
                fin;

                sur;
                si frente-libre entonces inicio
                    avanza;
                    busqueda_Armas;
                    norte;
                    mover;
                fin;

                este;
                si frente-libre entonces inicio
                    avanza;
                    busqueda_Armas;
                    oeste;
                    mover;
                fin;

                oeste;
                si frente-libre entonces inicio
                    avanza;
                    busqueda_Armas;
                    este;
                    mover;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion compara(armas) como inicio
        si junto-a-zumbador entonces inicio
            repetir 2 veces coge-zumbador;
            compara(sucede(armas));
        fin sino inicio
            Ini;
            repetir armas veces inicio
                si junto-a-zumbador entonces coge-zumbador;
            fin;
            repetir armas veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion cuenta como inicio
        buscaBeeper;
        busqueda_Armas;
        compara(0);
        si frente-libre entonces inicio
            avanza;
            cuenta;
        fin sino inicio
            si derecha-libre entonces inicio
                este;
                avanza;
                norte;
                cuenta;
            fin sino inicio
                apagate;
            fin;
        fin;
    fin;

    inicia-ejecucion
        Ini;
        cuenta;
        apagate;
    termina-ejecucion
finalizar-programa
