iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion orienta como inicio
        sur;
        mientras frente-libre hacer
            avanza;
        oeste;
        mientras frente-libre hacer
            avanza;
        norte;
    fin;
    define-nueva-instruccion lleva como inicio
        si frente-libre y orientado-al-sur entonces inicio
            avanza;
            lleva;
            norte;
            avanza;
        fin
        sino inicio
            oeste;
            si frente-libre y orientado-al-oeste entonces inicio
                avanza;
                lleva;
                este;
                avanza;
            fin
            sino inicio
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion busca como inicio
        si junto-a-zumbador entonces inicio
            sur;
            si frente-libre o derecha-libre entonces inicio
                si frente-libre entonces inicio
                    avanza;
                    si frente-libre o derecha-libre entonces inicio
                        norte;
                        avanza;
                        coge-zumbador;
                        si junto-a-zumbador entonces inicio
                            coge-zumbador;
                            sur;
                            lleva;
                        fin;
                        norte;
                        si frente-libre entonces inicio
                            avanza;
                            busca;
                            sur;
                            avanza;
                        fin;
                        este;
                        si frente-libre entonces inicio
                            avanza;
                            busca;
                            oeste;
                            avanza;
                        fin;
                        sur;
                        si frente-libre entonces inicio
                            avanza;
                            busca;
                            norte;
                            avanza;
                        fin;
                        oeste;
                        si frente-libre entonces inicio
                            avanza;
                            busca;
                            este;
                            avanza;
                        fin;
                    fin
                    sino inicio
                        norte;
                        avanza;
                    fin;
                fin
                sino inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        coge-zumbador;
                        sur;
                        lleva;
                    fin;
                    norte;
                    si frente-libre entonces inicio
                        avanza;
                        busca;
                        sur;
                        avanza;
                    fin;
                    este;
                    si frente-libre entonces inicio
                        avanza;
                        busca;
                        oeste;
                        avanza;
                    fin;
                    sur;
                    si frente-libre entonces inicio
                        avanza;
                        busca;
                        norte;
                        avanza;
                    fin;
                    oeste;
                    si frente-libre entonces inicio
                        avanza;
                        busca;
                        este;
                        avanza;
                    fin;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion buscauno como inicio
        si junto-a-zumbador entonces inicio
            sur;
            si frente-libre o derecha-libre entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                coge-zumbador;
                    sur;
                    lleva;
                fin;
                norte;
                si frente-libre entonces inicio
                    avanza;
                    buscauno;
                    sur;
                    avanza;
                fin;
                este;
                si frente-libre entonces inicio
                    avanza;
                    buscauno;
                    oeste;
                    avanza;
                fin;
                sur;
                si frente-libre entonces inicio
                    avanza;
                    buscauno;
                    norte;
                    avanza;
                fin;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    buscauno;
                    este;
                    avanza;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion compara (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            compara (sucede(n));
        fin
        sino inicio
            avanza;
            repetir n veces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin;
            fin;
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion recorre como inicio
        si frente-libre entonces inicio
            si junto-a-zumbador entonces inicio
                busca;
                orienta;
                compara (0);
                avanza;
            fin
            sino inicio
                avanza;
            fin;
            recorre;
        fin
        sino inicio
            si derecha-libre entonces inicio
                sur;
                mientras frente-libre hacer
                    avanza;
                este;
                avanza;
                norte;
                recorre;
            fin
            sino inicio
                si junto-a-zumbador entonces inicio
                    busca;
                    orienta;
                    compara (0);
                    avanza;
                    recorre;
                fin;
                orienta;
                avanza;
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                    sur;
                    avanza;
                    deja-zumbador;
                    norte;
                    avanza;
                fin;
                sur;
                avanza;
                norte;
                apagate;
            fin;
        fin;
    fin;
    define-nueva-instruccion proceso como inicio
        orienta;
        mientras no-junto-a-zumbador hacer inicio
            mientras frente-libre y no-junto-a-zumbador hacer
                avanza;
            si no-junto-a-zumbador entonces inicio
                si derecha-libre entonces inicio
                    sur;
                    mientras frente-libre hacer
                        avanza;
                    este;
                    avanza;
                    norte;
                fin;
            fin;
        fin;
        sur;
        si frente-bloqueado y derecha-bloqueada entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                norte;
                avanza;
                buscauno;
                orienta;
                este;
                avanza;
                buscauno;
                orienta;
                compara (0);
                si frente-libre entonces inicio
                    avanza;
                    recorre;
                fin
                sino inicio
                    mientras junto-a-zumbador hacer inicio
                        coge-zumbador;
                        sur;
                        avanza;
                        deja-zumbador;
                        norte;
                        avanza;
                    fin;
                    sur;
                    avanza;
                    norte;
                    apagate;
                fin;
            fin;
        fin
        sino inicio
            buscauno;
            orienta;
            compara (0);
            avanza;
            recorre;
        fin;
        avanza;
        recorre;
    fin;
    inicia-ejecucion
        proceso;
        apagate;
    termina-ejecucion
finalizar-programa