iniciar-programa

define-nueva-instruccion gira(z) como repetir z veces gira-izquierda;

define-nueva-instruccion recoger como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces deja-zumbador;
        repetir 4 veces inicio
            si frente-libre entonces inicio
                avanza;
                recoger;
                gira(2);
                avanza;
                gira(2);
            fin;
            gira(1);
        fin;
    fin;
fin;

    inicia-ejecucion

    mientras no-orientado-al-este hacer gira(1);
    mientras no-junto-a-zumbador y frente-libre hacer avanza;
    si no-junto-a-zumbador entonces apagate;
    gira(1);
    mientras junto-a-zumbador y frente-libre hacer avanza;
    gira(2);
    si no-junto-a-zumbador entonces avanza;
    mientras junto-a-zumbador y frente-libre hacer inicio
        coge-zumbador;
        gira(3);
        si frente-libre entonces inicio
            avanza;
            recoger;
            gira(2);
            avanza;
        fin;
        mientras no-orientado-al-este hacer gira(1);
        si frente-libre entonces inicio
            avanza;
            recoger;
            gira(2);
            avanza;
        fin;
        mientras no-orientado-al-sur hacer gira(1);
        deja-zumbador;
        avanza;
    fin;
    gira(3);
    mientras frente-libre hacer avanza;
    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;

        apagate;
    termina-ejecucion
finalizar-programa
