iniciar-programa
    define-nueva-instruccion gira-derecha como repetir 3 veces gira-izquierda;
    define-nueva-instruccion vuelta como repetir 2 veces gira-izquierda;
    define-nueva-instruccion principio como
    inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
    fin;
    define-nueva-instruccion encuentra como
    inicio
        mientras no-orientado-al-este hacer gira-izquierda;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si orientado-al-este y junto-a-zumbador entonces gira-izquierda;
        mientras no-junto-a-zumbador y orientado-al-este hacer vuelta;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si orientado-al-oeste y junto-a-zumbador entonces gira-derecha;
        si junto-a-zumbador entonces avanza;
    fin;
    define-nueva-instruccion corta como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si frente-libre entonces avanza;
            corta;
        fin;
        si orientado-al-oeste o orientado-al-este entonces
        inicio
            si frente-libre entonces
            inicio
                vuelta;
                avanza;
            fin sino
            inicio
            vuelta;
            fin;
            si orientado-al-oeste entonces gira-derecha;
            si orientado-al-este entonces gira-izquierda;
            avanza;
            si junto-a-zumbador entonces
            inicio
                corta;
            fin sino
            inicio
                gira-derecha;
                avanza;
                gira-izquierda;
                corta;
            fin;
        fin;
        si orientado-al-norte entonces
        inicio
            repetir 2 veces
            inicio
                gira-izquierda;
                mientras frente-libre hacer avanza;
            fin;
            sal-de-instruccion;
        fin;
    fin;
    define-nueva-instruccion rama como
    inicio
        gira-izquierda;
        avanza;
        si junto-a-zumbador entonces
        inicio
            corta;
            encuentra;
        fin sino
        inicio
            vuelta;
            repetir 2 veces avanza;
            si junto-a-zumbador entonces
            inicio
                corta;
                encuentra;
            fin sino
            inicio
                vuelta;
                avanza;
                gira-derecha;
                avanza;
                si junto-a-zumbador entonces
                inicio
                    rama;
                fin sino
                inicio
                    sal-de-instruccion;
                fin;
            fin;
        fin;
    fin;
    inicia-ejecucion
        encuentra;
        mientras junto-a-zumbador hacer rama;
        principio;
        apagate;
    termina-ejecucion
finalizar-programa
 